# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="Beyond the Red Line is based on Battlestar Galactica, using the fs2_open engine"
HOMEPAGE="http://www.game-warden.com/bsg/"
SRC_URI="http://www.unreal.ie/download/non-unreal/BtRLDemoInstaller.run
	http://files.plebian.net/uploads/bsg-btrl/BtRLDemoInstaller.run"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
RESTRICT="strip"

DEPEND=""
RDEPEND="
	x86? (
		media-libs/alsa-lib
		virtual/opengl
		>=media-libs/libsdl-1.2
		media-libs/openal
		x11-libs/libX11
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libXext
		x11-libs/libXrandr
		x11-libs/libXrender )
	amd64? ( app-emulation/emul-linux-x86-sdl )"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${PN}

src_unpack() {
	unpack_makeself BtRLDemoInstaller.run
	# Ignoring libs archive
	tar xf game_data.tar || die
}

src_install() {
	exeinto "${dir}"
	newexe bin/Linux/x86/glibc-2.1/btrl_demo.bin btrl-demo \
		|| die "newexe btrl-demo"

	insinto "${dir}"
	doins -r data || die "doins data"
	insinto "${dir}"/data
	doins *.vp || die

	newicon btrl.png ${PN}.png || die
	games_make_wrapper ${PN} ./${PN} "${dir}" "${dir}"
	make_desktop_entry ${PN} "Beyond the Red Line" ${PN}.png

	dodoc README

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	echo
	elog "To play the game, run:"
	elog " btrl-demo"
	echo

	if use amd64 ; then
		elog "If you are using ALSA, then you must have ALSA 32-bit emulation"
		elog "enabled in your kernel for this to function properly."
		echo
	fi
}