dev-python/hachoir-metadata/hachoir-metadata-0.10.0.ebuild

hachoir-metadata-0.10.0.ebuild (text/plain), 1.26 KB, created by Damien Thébault on 2007-04-15 12:07:25 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils

DESCRIPTION="Program to extract metadata using Hachoir library"
HOMEPAGE="http://hachoir.org"
SRC_URI="http://cheeseshop.python.org/packages/source/h/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="gnome kde"

RDEPEND=">=dev-lang/python-2.4
	>=dev-python/hachoir-core-0.9
	>=dev-python/hachoir-parser-0.10
	gnome? ( gnome-base/nautilus gnome-extra/zenity )
	kde? ( kde-base/konqueror )"
DEPEND="${RDEPEND}"

NAUTILUS_SCRIPTS_DIR="/usr/share/nautilus-scripts"
HOME_NAUTILUS_SCRIPT_DIR="~/.gnome2/nautilus-scripts"

src_install() {
	distutils_src_install
	if use gnome; then
		exeinto /usr/share/nautilus-scripts
		doexe gnome/hachoir
	fi
	if use kde; then
		exeinto /usr/bin
		doexe kde/hachoir-metadata-kde
		insinto /usr/share/apps/konqueror/servicemenus
		doins kde/hachoir.desktop
	fi
}

pkg_postinst() {
	if use gnome; then
		einfo "The nautilus script was installed in ${NAUTILUS_SCRIPTS_DIR}"
		einfo "Each user need to symlink it in his own home directory to" \
			"enable it :"
		einfo " $ mkdir -p ${HOME_NAUTILUS_SCRIPT_DIR}"
		einfo " $ ln -s ${NAUTILUS_SCRIPTS_DIR}/hachoir" \
			"${HOME_NAUTILUS_SCRIPT_DIR}"
	fi
}