alienarena-bin-20070225.ebuild

alienarena-bin-20070225.ebuild (text/plain), 2.70 KB, created by Régis Décamps on 2007-03-15 18:51:42 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PN="alienarena"

DESCRIPTION="The ultimate freeware deathmatch fragfest!"
HOMEPAGE="http://red.planetarena.org/"
SRC_URI="http://cor.planetquake.gamespy.com/codered/files/alienarena2007-linux${PV}-x86.zip"

LICENSE="free-noncomm"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="opengl sdl"

QA_EXECSTACK="${GAMES_PREFIX_OPT:1}/${MY_PN}/crx
	${GAMES_PREFIX_OPT:1}/${MY_PN}/crx.sdl"

UIRDEPEND="media-libs/jpeg
	virtual/glu
	virtual/opengl
	sdl? ( >=media-libs/libsdl-1.2.8-r1 )
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXext
	x11-libs/libXxf86dga
	x11-libs/libXxf86vm
	amd64? ( app-emulation/emul-linux-x86-sdl )"
RDEPEND="opengl? ( ${UIRDEPEND} )
	sdl? ( ${UIRDEPEND} )
	!games-fps/alienarena"
DEPEND="${RDEPEND}
	app-arch/unzip"

basedir=${WORKDIR}/${MY_PN}2007
S=${basedir}/source/linux
dir=${GAMES_PREFIX_OPT}/${MY_PN}

#QA_EXECSTACK="${dir:1}/crded
#	${dir:1}/crx
#	${dir:1}/crx.sdl"

src_unpack() {
	unpack ${A}
	cd "${basedir}"

	# Startup scripts
	sed -i \
		-e "s:/usr/local/games/${MY_PN}2007:.:" \
		AlienArena || die "sed AlienArena failed"

	cp -f AlienArena{,.sdl}
	sed -i \
		-e "s:crx:crx.sdl:" \
		AlienArena.sdl || die "sed AlienArena.sdl failed"
}

src_compile() { :; }

src_install() {
	local icon=${MY_PN}.xpm
	doicon "${basedir}/${icon}" || die "doicon failed"

	# Always install the dedicated executable
	exeinto "${dir}"
	doexe "${basedir}"/AlienArenaDedicated \
		|| die "doexe AlienArenaDedicated failed"
	games_make_wrapper ${MY_PN}-ded ./AlienArenaDedicated "${dir}"

	if use opengl || use sdl ; then
		# SDL implies OpenGL
		games_make_wrapper ${MY_PN} ./AlienArena "${dir}" "${dir}"
		if use sdl ; then
			games_make_wrapper ${MY_PN}-sdl ./AlienArena.sdl "${dir}" "${dir}"
			# Distinguish between OpenGL and SDL versions
			make_desktop_entry ${MY_PN} "Alien Arena (OpenGL)" "${icon}"
			make_desktop_entry ${MY_PN}-sdl "Alien Arena (SDL)" "${icon}"
		else
			make_desktop_entry ${MY_PN} "Alien Arena" "${icon}"
		fi
	fi

	insinto "${dir}"
	doins -r "${basedir}"/{arena,botinfo,data1} || die "doins -r failed"

	exeinto "${dir}"
	if use amd64 ; then
		doexe "${basedir}"/{AlienArena*,crded.x86_64,crx.x86_64,crx.sdl.x86_64} || die "doexe failed"
	else
		doexe "${basedir}"/{AlienArena*,crded.i686,crx.i686,crx.sdl.i686} || die "doexe failed"
	fi


	if $(diff -q "${D}/${dir}"/{arena,data1}/gamei386.so) ; then
		# Replace duplicate file with symlink
		if use amd64 ; then
			dosym "${dir}"/{arena,data1}/gamex86_64.so || die "dosym failed"
		else
			dosym "${dir}"/{arena,data1}/gamei386.so || die "dosym failed"
		fi
	fi

	dodoc "${basedir}"/README.txt || die

	prepgamesdirs
}