sorry, there were typos in the above version.

blender-2.43.ebuild (text/plain), 3.32 KB, created by Cornelius Weig on 2007-03-12 00:08:51 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit multilib flag-o-matic eutils python

#IUSE="jpeg mozilla png sdl static truetype"
IUSE="blender-game ffmpeg jpeg nls ode openal openexr png sdl yafray"
FFMPEG_SNAP="0.4.9-p20061016"
DESCRIPTION="3D Creation/Animation/Publishing System"
HOMEPAGE="http://www.blender.org/"
SRC_URI="http://download.blender.org/source/${P}.tar.gz
		 ffmpeg? ( mirror://gentoo/ffmpeg-${FFMPEG_SNAP}.tar.bz2 )"

SLOT="0"
LICENSE="|| ( GPL-2 BL )"
KEYWORDS="~x86"

RDEPEND=">=dev-libs/openssl-0.9.6
	ffmpeg? ( >=media-video/ffmpeg-${FFMPEG_SNAP/-/_}
			~media-libs/x264-svn-20061014 )
	jpeg? ( media-libs/jpeg )
	media-libs/tiff
	nls? ( >=media-libs/freetype-2.0
			virtual/libintl
			>=media-libs/ftgl-2.1 )
	ode? ( dev-games/ode )
	openal? ( media-libs/openal
			media-libs/freealut )
	openexr? ( media-libs/openexr )
	png? ( media-libs/libpng )
	sdl? ( >=media-libs/libsdl-1.2 )
	virtual/opengl
	yafray? ( >=media-gfx/yafray-0.0.8 )"

DEPEND="dev-util/scons
	|| ( x11-libs/libXt virtual/x11 )
	${RDEPEND}"

blend_with() {
	local UWORD="$2"
	if [ -z "${UWORD}" ]; then
		UWORD="$1"
	fi
	if useq $1; then
		echo "WITH_BF_${UWORD}=1" | tr '[:lower:]' '[:upper:]' \
			>> ${S}/user-config.py
	else
		echo "WITH_BF_${UWORD}=0" | tr '[:lower:]' '[:upper:]' \
			>> ${S}/user-config.py
	fi
	return 0
}

src_unpack() {
	unpack ${A}
	cd ${S}/release/plugins
	chmod 755 bmake
	rmdir include
	cp -pPR ${S}/source/blender/blenpluginapi include

	cd ${S}
	epatch ${FILESDIR}/blender-2.37-dirs.patch

	if use ffmpeg ; then
		cd ${S}/extern
		mv ffmpeg/Makefile ffmpeg/common.mak ${T}
		unpack ffmpeg-${FFMPEG_SNAP}.tar.bz2
		mv ${T}/Makefile ${T}/common.mak ffmpeg
	fi
	touch ${S}/user-config.py
}


src_compile() {
	for arg in 'blender-game gameengine' ffmpeg jpeg 'nls international' openal\
		openexr png sdl yafray; do
			blend_with ${arg}
	done

	# pass compiler flags to the scons build system
	echo "CFLAGS += '${CFLAGS}'" >> ${S}/user-config.py
	echo "CCFLAGS += ['${CXXFLAGS//' '/','}']" >> ${S}/user-config.py
	# disable blender-player and iconv
	echo "WITH_BF_PLAYER=0" >> ${S}/user-config.py
	echo "WITH_BF_ICONV=0" >> ${S}/user-config.py

	# scons uses -l differently -> remove it
	scons ${MAKEOPTS/-l[0-9]} -h > scons.config
	scons ${MAKEOPTS/-l[0-9]} || die \
	"!!! Please add ${S}/scons.config when filing bugs reports to bugs.gentoo.org"

	cd ${S}/release/plugins
	emake || die
}

src_install() {
	exeinto /usr/bin/
	doexe ${WORKDIR}/install/linux2/blender

	dodir /usr/share/${PN}

	exeinto /usr/$(get_libdir)/${PN}/textures
	doexe ${S}/release/plugins/texture/*.so
	exeinto /usr/$(get_libdir)/${PN}/sequences
	doexe ${S}/release/plugins/sequence/*.so
	insinto /usr/include/${PN}
	doins ${S}/release/plugins/include/*.h

	if use nls ; then
		mv ${WORKDIR}/install/linux2/.blender/{.Blanguages,.bfont.ttf} \
			${D}/usr/share/${PN}
		mv ${WORKDIR}/install/linux2/.blender/locale \
			${D}/usr/share/locale
	fi

	mv ${WORKDIR}/install/linux2/.blender/scripts ${D}/usr/share/${PN}

	insinto /usr/share/pixmaps
	doins ${FILESDIR}/${PN}.png
	insinto /usr/share/applications
	doins ${FILESDIR}/${PN}.desktop

	dodoc COPYING INSTALL README
}

pkg_preinst(){
	if [ -h "${ROOT}/usr/$(get_libdir)/blender/plugins/include" ];
	then
		rm -f ${ROOT}/usr/$(get_libdir)/blender/plugins/include
	fi
}