aide-0.13.1.ebuild

aide-0.13.1.ebuild (text/plain), 3.38 KB, created by MATSUU Takuto (RETIRED) on 2007-02-22 17:07:58 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/aide/aide-0.10_p20040917-r1.ebuild,v 1.2 2005/12/16 13:06:00 flameeyes Exp $

WANT_AUTOMAKE=latest
WANT_AUTOCONF=latest

inherit autotools eutils multilib

DESCRIPTION="AIDE (Advanced Intrusion Detection Environment) is a replacement for Tripwire"
HOMEPAGE="http://aide.sourceforge.net/"
SRC_URI="mirror://sourceforge/aide/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="acl audit curl mhash nls postgres selinux static xattr zlib"

DEPEND="acl? ( sys-apps/acl )
	audit? ( sys-proccess/audit )
	curl? ( net-misc/curl )
	mhash? ( >=app-crypt/mhash-0.9.2 )
	!mhash? ( dev-libs/libgcrypt )
	nls? ( sys-devel/gettext )
	postgres? ( dev-db/postgresql )
	selinux? ( sys-libs/libselinux )
	zlib? ( sys-libs/zlib )"


RDEPEND="!static? ( ${DEPEND} )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-gentoo.patch

	if ! use mhash ; then
		# dev-libs/libgcrypt doesn't support whirlpool algorithm
		sed -i -e 's/\+whirlpool//' doc/aide.conf.in || die
	fi

	if ! use selinux ; then
		sed -i -e 's/\+selinux//' doc/aide.conf.in || die
	fi

	if ! use xattr ; then
		sed -i -e 's/\+xattrs//' doc/aide.conf.in || die
	fi

	if ! use acl ; then
		sed -i -e 's/\+acl//' doc/aide.conf.in || die
	fi
	eautoreconf
}

src_compile() {
	local myconf="--sysconfdir=/etc/aide"

	# --without-* borked
	use zlib && myconf="${myconf} --with-zlib"
	use nls  && myconf="${myconf} --with-locale"
	use postgres && myconf="${myconf} --with-psql"
	use selinux && myconf="${myconf} --with-selinux"
	use curl && myconf="${myconf} --with-curl"
	use acl && myconf="${myconf} --with-posix-acl"
	use xattr && myconf="${myconf} --with-xattr"
	use audit && myconf="${myconf} --with-audit"
	use static && myconf="${myconf} --enable-static"

	# If you use dev-libs/libgcrypt, --without-mhash is needed.
	use mhash \
		&& myconf="${myconf} --with-mhash" \
		|| myconf="${myconf} --with-gcrypt --without-mhash"

	econf ${myconf} || die 
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	keepdir /var/lib/aide
	keepdir /var/log/aide

	insinto /etc/aide
	doins "${FILESDIR}"/aide.conf
	# doins doc/aide.conf

	dosbin "${FILESDIR}"/aideinit

	exeinto /etc/cron.daily
	doexe "${FILESDIR}"/aide.cron

	dodoc ChangeLog AUTHORS NEWS README
	dohtml doc/manual.html
}

pkg_postinst() {
	chown root:0 /var/lib/aide
	chmod 0755 /var/lib/aide

	echo
	einfo "A sample configuration file has been installed as"
	einfo "/etc/aide/aide.conf.  Please edit to meet your needs."
	einfo "Read the aide.conf(5) manual page for more information."
	einfo "A cron file has been installed in /etc/cron.daily/aide.cron"
	einfo "A helper script, aideinit, has been installed and can"
	einfo "be used to make AIDE management easier. Please run"
	einfo "aideinit --help for more information"
	echo

	if use postgres; then
		einfo "Due to a bad assumption by aide, you must issue the following"
		einfo "command after the database initialization (aide --init ...):"
		einfo
		einfo 'psql -c "update pg_index set indisunique=false from pg_class \\ '
		einfo "  where pg_class.relname='TABLE_pkey' and \ "
		einfo '  pg_class.oid=pg_index.indexrelid" -h HOSTNAME -p PORT DBASE USER'
		einfo
		einfo "where TABLE, HOSTNAME, PORT, DBASE, and USER are the same as"
		einfo "your aide.conf."
		echo
	fi
}