aide-0.13.1.ebuild

aide-0.13.1.ebuild (text/plain), 2.88 KB, created by Daniel Black (RETIRED) on 2007-02-21 12:12:15 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/aide/aide-0.10_p20040917-r1.ebuild,v 1.2 2005/12/16 13:06:00 flameeyes Exp $

inherit autotools eutils

DESCRIPTION="AIDE (Advanced Intrusion Detection Environment) is a replacement for Tripwire"
HOMEPAGE="http://aide.sourceforge.net/"
SRC_URI="mirror://sourceforge/aide/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="nls postgres zlib crypt static selinux curl acl xattr"

DEPEND="curl? ( net-misc/curl )
		selinux? ( sys-libs/libselinux )
		nls? ( sys-devel/gettext )
		zlib? ( sys-libs/zlib )
		crypt? ( dev-libs/libgcrypt )
		!crypt? ( app-crypt/mhash )
		postgres? ( dev-db/postgresql )
		acl? ( sys-apps/acl )"
DEPEND="!static? ( ${DEPEND} )"

#src_unpack() {
#	unpack ${A}
#	cd "${S}"
#	epatch "${FILESDIR}"/${P}-locale.diff
#	eautoconf
#}
#
src_compile() {
	econf \
		$(use_with zlib) \
		$(use_with nls locale) \
		$(use_with crypt gcrypt) \
		$(use_with !crypt mhash ) \
		$(use_with postgres psql) \
		$(use_with selinux ) \
		$(use_with curl ) \
		$(use_with acl posix-acl ) \
		$(use_with xattr ) \
		$(use_enable static) \
		--sysconfdir=/etc/aide \
		--with-extra-lib=/usr/lib \
		|| die
	emake || die
}

src_test() {
	# aide abort()'s inside the sandbox for some reason
	if ! has sandbox ${FEATURES};
	then
		src/aide --init -c doc/aide.conf -V20 \
			|| die "failed to initialise database"
		mv aide.db.new doc/aide.db
		make check || die "failed self test"
	fi
}

src_install() {
	make DESTDIR="${D}" install || die
	use nls || rm -rf ${D}/usr/lib/locale

	keepdir /var/lib/aide
	keepdir /var/log/aide

	insinto /etc/aide
	doins "${FILESDIR}"/aide.conf

	dosbin "${FILESDIR}"/aideinit aideinit

	exeinto /etc/cron.daily
	newexe ${FILESDIR}/aide.cron aide.cron

	dodoc ChangeLog AUTHORS NEWS README
	dohtml doc/manual.html
}

pkg_postinst() {
	chown root:0 /var/lib/aide
	chmod 0755 /var/lib/aide

	echo
	einfo "A sample configuration file has been installed as"
	einfo "/etc/aide/aide.conf.  Please edit to meet your needs."
	einfo "Read the aide.conf(5) manual page for more information."
	einfo "A cron file has been installed in /etc/cron.daily/aide.cron"
	einfo "A helper script, aideinit, has been installed and can"
	einfo "be used to make AIDE management easier. Please run"
	einfo "aideinit --help for more information"
	echo

	if use postgres; then
		einfo "Due to a bad assumption by aide, you must issue the following"
		einfo "command after the database initialization (aide --init ...):"
		einfo
		einfo 'psql -c "update pg_index set indisunique=false from pg_class \\ '
		einfo "  where pg_class.relname='TABLE_pkey' and \ "
		einfo '  pg_class.oid=pg_index.indexrelid" -h HOSTNAME -p PORT DBASE USER'
		einfo
		einfo "where TABLE, HOSTNAME, PORT, DBASE, and USER are the same as"
		einfo "your aide.conf."
		echo
	fi
}