suggested ebuild

virtualbox-bin-1.3.6.ebuild (text/plain), 2.48 KB, created by Johannes Ballé on 2007-02-20 22:07:52 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header $

inherit eutils linux-mod qt3

MY_P=VirtualBox_${PV}_Linux_x86.run

DESCRIPTION="Full virtualizer for x86 hardware"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://www.virtualbox.org/download/${PV}/${MY_P}"

LICENSE="PUEL"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="additions doc"

DEPEND=">=sys-libs/glibc-2.3.5"
RDEPEND="!app-emulation/virtualbox
	amd64? (
		>=app-emulation/emul-linux-x86-baselibs-2.5.5-r3
		>=app-emulation/emul-linux-x86-qtlibs-3.4.4
		app-emulation/emul-linux-x86-compat
		app-emulation/emul-linux-x86-xlibs
		app-emulation/emul-linux-x86-sdl )
	x86? (
		virtual/xft
		x11-libs/libX11
		x11-libs/libXtst
		x11-libs/libXext
		x11-libs/libXt
		x11-libs/libICE
		x11-libs/libSM
		x11-libs/libXrender
		=virtual/libstdc++-3.3
		x11-libs/libXcursor
		media-libs/libsdl
		$(qt_min_version 3.3.5) )"

S="${WORKDIR}"

RESTRICT="primaryuri"

BUILD_PARAMS="KERN_DIR=${KV_DIR} KERNOUT=${KV_OUT_DIR}"
BUILD_TARGETS="all"
MODULE_NAMES="vboxdrv(misc:${S}/src)"

pkg_setup() {
	linux-mod_pkg_setup
	check_license
}

src_unpack() {
	unpack_makeself ${A}
	unpack ./VirtualBox.tar.bz2
}

src_install() {
	linux-mod_src_install
	cd "${S}"

	# desktop entry
	insinto /usr/share/pixmaps
	newins VBox.png virtualbox.png
	insinto /usr/share/applications
	newins VirtualBox.desktop virtualbox.desktop
	dosed -e "10d" /usr/share/applications/virtualbox.desktop
	dosed -e "5d" /usr/share/applications/virtualbox.desktop
	dosed -e "s/VBox.png/virtualbox.png/" /usr/share/applications/virtualbox.desktop

	insinto /opt/VirtualBox
	exeinto /opt/VirtualBox

	doins -r *.so *.gc *.r0 components
	use additions && doins -r additions
	use doc && dodoc UserManual.pdf VirtualBox.chm

	doexe VBox{Manage,SDL,SVC,XPCOMIPCD,VRDP} VirtualBox

	doexe "${FILESDIR}/wrapper.sh"
	dosym /opt/VirtualBox/wrapper.sh /usr/bin/VirtualBox
	dosym /opt/VirtualBox/wrapper.sh /usr/bin/VBoxManage
	dosym /opt/VirtualBox/wrapper.sh /usr/bin/VBoxSDL

	# udev rule for vboxdrv
	dodir /etc/udev/rules.d
	echo 'KERNEL=="vboxdrv", GROUP="vboxusers" MODE=660' >"${D}/etc/udev/rules.d/60-virtualbox.rules"
}

pkg_preinst() {
	enewgroup vboxusers
}

pkg_postinst() {
	if use amd64; then
		elog ""
		elog "To avoid the nmi_watchdog bug and load the vboxdrv module"
		elog "you may need to update your bootloader configuration and pass the option:"
		elog "nmi_watchdog=0"
	fi
	elog ""
	elog "You must be in the vboxusers group to use VirtualBox."
	elog ""
}