taskjuggler-2.3.1.ebuild (version bump + cleanups)

taskjuggler-2.3.1.ebuild (text/plain), 2.19 KB, created by Przemyslaw Maciag (RETIRED) on 2007-02-04 14:41:21 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit qt3

DESCRIPTION="project management tool for Linux and UNIX system-based operating systems"
HOMEPAGE="http://www.taskjuggler.org/"
SRC_URI="http://www.taskjuggler.org/download/${P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~x86"

IUSE="arts doc kde"
SLOT="0"

RDEPEND="$(qt_min_version 3.3)
	kde? ( >=kde-base/kdelibs-3
		|| ( kde-base/libkdepim kde-base/kdepim  )
		|| ( kde-base/libkcal kde-base/kdepim ) )
	>=dev-perl/Class-MethodMaker-2.02
	dev-perl/Date-Calc
	dev-perl/PostScript-Simple
	dev-perl/XML-Parser
	net-print/poster"

DEPEND="${RDEPEND}
	doc? ( =app-text/docbook-xml-dtd-4.3* app-text/docbook-sgml-utils
		app-text/openjade app-text/jadetex dev-libs/libxslt )
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}
	cd ${S}

	# 'db2html' does not know '--xencoding utf8' and is called 'docbook2html' in gentoo
	# also 'db2ps --pdf' should be 'docbook2pdf' and 'db2ps' should be 'docbook2ps'
	# see http://lists.suse.com/archive/taskjuggler-devel/2005-Mar/0011.html
	sed -i -e 's/--xencoding utf-8//g' docs/en/Makefile.*
	sed -i -e 's/db2ps --pdf/docbook2pdf/g' docs/en/Makefile.*
	sed -i -e 's/db2ps/docbook2ps/g' docs/en/Makefile.*

	# Correct invalid DTD paths to the correct references
	sed -i -e 's:/usr/share/xml/docbook/schema/dtd/4.3/docbookx.dtd:docbookx.dtd:g' docs/en/taskjuggler.xml.in
	sed -i -e 's:DocBook V4.3:DocBook XML V4.3:g' docs/en/taskjuggler.xml.in
	sed -i -e 's:/usr/share/xml/docbook/schema/dtd/4.3/docbookx.dtd:docbookx.dtd:g' docs/en/kde-doc.patch
	sed -i -e 's:DocBook V4.3:DocBook XML V4.3:g' docs/en/kde-doc.patch
	sed -i -e 's:/usr/share/sgml/docbook/dtd/4.2xml/docbookx.dtd:docbookx.dtd:g' docs/en/PropertyReference.xml
}

src_compile() {
	local myconf="--with-kde-support"
	use kde \
		&& myconf="${myconf}=yes" \
		|| myconf="${myconf}=no"

	econf \
		${myconf} \
		$(use_with arts) \
		--disable-docs \
		|| die "configure failed"
#		$(use_enable doc docs) \

	emake || die "emake failed"
}

src_install() {
	make install DESTDIR=${D} || die "install failed"
	if use kde; then
		cd Contrib/kate
		make install DESTDIR=${D} || die "install kate-addons failed"
	fi
}