seahorse-0.9.10.ebuild

seahorse-0.9.10.ebuild (text/plain), 1.87 KB, created by Gilles Dartiguelongue (RETIRED) on 2007-02-03 21:37:11 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/seahorse-0.9.10.ebuild,v 1.6 2007/01/11 22:10:52 eva Exp $

inherit gnome2 eutils autotools flag-o-matic

DESCRIPTION="Gnome front end to gnupg"
HOMEPAGE="http://www.gnome.org/projects/seahorse/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~x86 ~amd64"
IUSE="avahi dbus gnome ldap libnotify test"

RDEPEND="
	>=gnome-base/libgnomeui-2.0
	>=gnome-base/gnome-vfs-2.0
	>=gnome-base/libglade-2.0
	>=gnome-base/gconf-2.0
	>=x11-libs/gtk+-2.8
	>=dev-libs/glib-2.10.0
	|| ( =app-crypt/gnupg-1.4* >=app-crypt/gnupg-2.0.1-r2 )
	>=app-crypt/gpgme-1.0.0
	>=net-libs/libsoup-2.2
	  x11-misc/shared-mime-info
	gnome? (
		>=app-editors/gedit-2.6.0
		>=gnome-base/nautilus-2.10
		>=gnome-base/gnome-keyring-0.4
		>=www-client/epiphany-2.14
		>=gnome-base/libbonobo-2
		>=gnome-base/libbonoboui-2
	)
	avahi? ( net-dns/avahi ) 
	dbus? ( || ( >=dev-libs/dbus-glib-0.70 >=sys-apps/dbus-0.35 ) )
	ldap? ( net-nds/openldap )
	libnotify? ( >=x11-libs/libnotify-0.3 )"

DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.34
	>=dev-util/pkgconfig-0.19
	>=app-text/scrollkeeper-0.3"

DOCS="AUTHORS ChangeLog NEWS README TODO THANKS"

# currently not building if j>1
MAKEOPTS="${MAKEOPTS} -j1"

src_unpack() {
	gnome2_src_unpack
	epatch ${FILESDIR}/${PN}-0.9.10-configure.patch
	epatch ${FILESDIR}/${PN}-0.9.10-libseahorse.patch
	AT_M4DIR="m4" eautoreconf
}

pkg_setup() {
	append-ldflags $(bindnow-flags)
	G2CONF="${G2CONF} \
      $(use_enable avahi sharing) \
	  $(use_enable ldap) \
	  $(use_enable libnotify) \
	  $(use_enable dbus) \
	  $(use_enable gnome gedit) \
	  $(use_enable gnome nautilus) \
	  $(use_enable gnome gnome-keyring) \
	  $(use_enable test tests) \
	  --enable-ssh \
	  --localstatedir=${D}/var/lib/scrollkeeper/ \
	  --disable-update-mime-database"
}