mailutils-1.1.ebuild (Version 1)

mailutils-1.1.ebuild (text/plain), 2.59 KB, created by Martin von Gagern on 2007-01-30 17:02:50 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

inherit eutils
DESCRIPTION="A useful collection of mail servers, clients, and filters."
HOMEPAGE="http://savannah.gnu.org/projects/${PN}/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="alpha ~amd64 ~ppc ~sparc x86"
IUSE="berkdb bidi gdbm gnutls guile iodbc kerberos mailwrapper mysql nls
      odbc pam postgres radius readline sasl"
PROVIDE="virtual/mailx"
DEPEND="sys-libs/ncurses
	berkdb? ( sys-libs/db )
	bidi? ( dev-libs/fribidi )
	gdbm? ( sys-libs/gdbm )
	gnutls? ( net-libs/gnutls )
	guile? ( dev-scheme/guile )
	iodbc? ( dev-db/libiodbc )
	!iodbc? ( odbc? ( dev-db/unixODBC ) )
	kerberos? ( virtual/krb5 )
	mysql? ( virtual/mysql )
	nls? ( sys-devel/gettext )
	postgres? ( dev-db/postgresql )
	radius? ( || ( net-dialup/gnuradius
	               net-dialup/freeradius
	               net-dialup/cistronradius ) )
	readline? ( sys-libs/readline )
	sasl? ( net-libs/libgsasl )
       "
RDEPEND="${DEPEND}
	 virtual/mta
	 !virtual/mailx
	 !mail-client/nmh
	 !mail-client/elm
	"

src_unpack() {
	unpack ${A}
	cd ${S}

	#epatch ${FILESDIR}/${P}-mh-Makefile.in.patch
	#epatch ${FILESDIR}/${PN}-IDEF0954-IDEF0955.patch
	#epatch ${FILESDIR}/${PN}-IDEF0956.patch
	#epatch ${FILESDIR}/${PN}-IDEF0957.patch
	#epatch ${FILESDIR}/${PN}-getline.diff
	#epatch ${FILESDIR}/${PN}-SQLinjection.patch
	#epatch ${FILESDIR}/${P}-imap4d-format-string.patch
	#epatch ${FILESDIR}/${P}-imap4d-gcc4.0-ftbfs.patch
}

src_compile() {

	local myconf="--localstatedir=/var --sharedstatedir=/var"

	myconf="${myconf} --enable-mh-utils"
	myconf="${myconf} --enable-sendmail"
	myconf="${myconf} --without-dbm"
	myconf="${myconf} --without-ndbm"

	myconf="${myconf} $(use_with berkdb berkeley-db)"
	myconf="${myconf} $(use_with bidi fribidi)"
	myconf="${myconf} $(use_with gdbm)"
	myconf="${myconf} $(use_with gnutls)"
	myconf="${myconf} $(use_with sasl gsasl)"
	myconf="${myconf} $(use_with guile)"
	myconf="${myconf} $(use_with kerberos gssapi)"
	myconf="${myconf} $(use_with mysql)"
	myconf="${myconf} $(use_enable nls)"
	myconf="${myconf} $(use_enable pam)"
	myconf="${myconf} $(use_with postgres)"
	myconf="${myconf} $(use_enable radius)"
	myconf="${myconf} $(use_with readline)"

	if use iodbc; then
	  myconf="${myconf} --with-odbc=iodbc"
	else
	  myconf="${myconf} $(use_with odbc)"
	fi

	econf ${myconf} || die "configure failed"
	emake || die "compile failed"
}

src_install() {
	make DESTDIR=${D} install || die
	# mail.rc stolen from mailx, resolve bug #37302.
	insinto /etc
	doins "${FILESDIR}/mail.rc"
}