# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games toolchain-funcs

DESCRIPTION="A 3D MMORPG virtual world entirely built and owned by its residents"
HOMEPAGE="http://secondlife.com/"
SRC_URI="http://secondlife.com/developers/opensource/downloads/2007/01/slviewer-src-${PV}.tar.gz
	http://secondlife.com/developers/opensource/downloads/2007/01/slviewer-linux-libs-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="fmod"
RESTRICT="mirror"

RDEPEND=">=x11-libs/gtk+-2
	=dev-libs/apr-1*
	=dev-libs/apr-util-1*
	dev-libs/boost
	net-misc/curl
	dev-libs/openssl
	media-libs/freetype
	media-libs/jpeg
	media-libs/libsdl
	media-libs/mesa
	media-libs/libogg
	media-libs/libvorbis
	fmod? ( x86? ( >=media-libs/fmod-3.75 ) )
	=sys-libs/db-4.2*
	dev-libs/expat
	sys-libs/zlib
	>=dev-libs/xmlrpc-epi-0.51
	dev-libs/ELFIO
	media-libs/openjpeg
	media-fonts/kochi-substitute"

DEPEND="${RDEPEND}
	dev-util/scons
	dev-util/pkgconfig
	sys-devel/flex
	sys-devel/bison"

S="${WORKDIR}/linden"

dir="${GAMES_DATADIR}/${PN}"

src_unpack() {
	unpack ${A}

	rm -rf "${S}"/indra/libraries/i686-linux/*
	rm -rf "${S}"/indra/libraries/include/*

	cd "${S}"/indra

	# http://svn.mandriva.com/cgi-bin/viewvc.cgi/packages/cooker/secondlife/current/SOURCES/slviewer-src-20070108c-no_fmod.patch?revision=106264
	if ! use fmod || [ "${ARCH}" != "x86" ] ; then
		epatch "${FILESDIR}"/slviewer-src-20070108c-no_fmod.patch
	fi
	epatch "${FILESDIR}"/${P}-gentoo.patch

	sed -i -e "s/gcc_bin = .*$/gcc_bin = '$(tc-getCXX)'/" SConstruct || die
}

src_compile() {
	local myarch

	if [ "${ARCH}" == "x86" ] ; then
		myarch="i686"
	elif [ "${ARCH}" == "amd64" ] ; then
		myarch="x86_64"
	elif [ "${ARCH}" == "ppc" ] ; then
		myarch="powerpc"
	fi

	cd "${S}"/indra
	CLIENT_CPPFLAGS="${CXXFLAGS}" TEMP_BUILD_DIR="/" \
		scons BUILD=release ARCH="${myarch}" BTARGET=client DISTCC=no || die
}

src_install() {
	cd "${S}"/indra/newview/

	insinto "${dir}"
	doins featuretable.txt featuretable_mac.txt gpu_table.txt || die
	doins -r app_settings character fonts help skins res-sdl || die

	insinto "${dir}"/app_settings/
	doins "${S}"/scripts/messages/message_template.msg || die

	exeinto "${dir}"
	doexe linux_tools/launch_url.sh || die
	newexe linux_tools/wrapper.sh secondlife || die
	newexe ../linux_crash_logger/linux-crash-logger-*-bin* linux-crash-logger.bin || die

	exeinto "${dir}"/bin/
	newexe secondlife-*-bin* do-not-directly-run-secondlife-bin || die

	keepdir "${dir}"/lib

	dosym /usr/share/fonts/kochi-substitute/kochi-mincho-subst.ttf /usr/share/games/secondlife/unicode.ttf

	games_make_wrapper secondlife ./secondlife "${dir}"
	newicon res/ll_icon.ico secondlife.ico || die
	make_desktop_entry secondlife "Second Life" secondlife.ico

	dodoc releasenotes.txt
	newdoc licenses-linux.txt licenses.txt
	newdoc linux_tools/client-readme.txt README-linux.txt

	dohtml lsl_guide.html

	prepgamesdirs
}