# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games toolchain-funcs

DESCRIPTION="A 3D MMORPG virtual world entirely built and owned by its residents"
HOMEPAGE="http://secondlife.com/"
SRC_URI="http://secondlife.com/developers/opensource/downloads/slviewer-src-${PV}.tar.gz"
# http://secondlife.com/developers/opensource/downloads/slviewer-linux-libs-${PV}.tar.gz

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~x86"
# KEYWORDS="-* ~amd64 ~ppc ~x86"
IUSE=""

RDEPEND=">=x11-libs/gtk+-2
	=dev-libs/apr-1*
	=dev-libs/apr-util-1*
	dev-libs/boost
	net-misc/curl
	dev-libs/openssl
	media-libs/freetype
	media-libs/jpeg
	media-libs/libsdl
	media-libs/mesa
	media-libs/libogg
	media-libs/libvorbis
	x86? ( >=media-libs/fmod-3.75 )
	=sys-libs/db-4.2*
	dev-libs/expat
	sys-libs/zlib
	>=dev-libs/xmlrpc-epi-0.51
	dev-libs/ELFIO
	media-libs/openjpeg
	media-fonts/kochi-substitute"

DEPEND="${RDEPEND}
	dev-util/scons
	dev-util/pkgconfig
	dev-util/byacc"

S="${WORKDIR}/linden"

src_unpack() {
	unpack ${A}
	cd "${S}"/indra

	epatch "${FILESDIR}"/${P}-gentoo.patch
	epatch "${FILESDIR}"/slviewer-src-${PV}-cplusplus.patch
	epatch "${FILESDIR}"/slviewer-src-${PV}-extra.patch
	epatch "${FILESDIR}"/slviewer-src-${PV}-llembeddeditems.patch
	epatch "${FILESDIR}"/slviewer-src-${PV}-uictrlfactory.patch
	epatch "${FILESDIR}"/slviewer-src-${PV}-datapath.patch
	if [ "${ARCH}" != "x86" ] ; then
		epatch "${FILESDIR}"/slviewer-src-${PV}-no_fmod.patch
	fi
	epatch "${FILESDIR}"/slviewer-src-${PV}-ELFIO.patch
	epatch "${FILESDIR}"/slviewer-llfont.patch
	if [ "${ARCH}" == "amd64" ] ; then
		epatch "${FILESDIR}"/slviewer-src-${PV}-x86_64.patch
	fi


	sed -i -e "s/gcc_bin = .*$/gcc_bin = '$(tc-getCXX)'/" SConstruct || die
	# sed -i -e "s/yacc/yacc -b y/" SConstruct || die
	sed -i -e "s/yacc/byacc/" SConstruct || die
}

src_compile() {
	local myarch

	if [ "${ARCH}" == "x86" ] ; then
		myarch="i686"
	elif [ "${ARCH}" == "amd64" ] ; then
		myarch="x86_64"
	elif [ "${ARCH}" == "ppc" ] ; then
		myarch="powerpc"
	fi

	cd "${S}"/indra
	CLIENT_CPPFLAGS="${CXXFLAGS}" TEMP_BUILD_DIR="/" \
	scons \
		BUILD=release \
		ARCH="${myarch}" \
		BTARGET=client \
		DISTCC=no || die
}

src_install() {
	cd "${S}"/indra/newview/

	insinto /usr/share/games/secondlife/
	doins gpu_table.txt linux_tools/launch_url.sh || die
	doins -r app_settings character fonts help skins res-sdl || die


	doins "${S}"/scripts/messages/message_template.msg || die
	

	newbin linux_tools/wrapper.sh secondlife || die
	
	exeinto /usr/share/games/secondlife/bin/
	newexe secondlife-*-bin do-not-directly-run-secondlife-bin || die

	dosym /usr/share/fonts/kochi-substitute/kochi-mincho-subst.ttf /usr/share/games/secondlife/unicode.ttf

	dodoc featuretable.txt licenses-linux.txt releasenotes.txt linux_tools/client-readme.txt

}