# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit toolchain-funcs

DESCRIPTION="small and fast portage helper tools written in C"
HOMEPAGE="http://www.gentoo.org/"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86"
IUSE="" # python

DEPEND=""

src_compile() {
	tc-export CC
	# python support not ready yet
	# use python && export PYTHON=1
	unset PYTHON
	emake || die "emake failed"
}

src_install() {
	dobin q || die "dobin failed"
	doman man/*.[0-9]
	for applet in $(<applet-list) ; do
		dosym q /usr/bin/${applet}
	done

	dodir /etc/portage/bin/

cat <<__EOF__ > "${D}"/etc/portage/bin/post_sync
#!/bin/sh
# Copyright 2006-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

if [ -d /etc/portage/postsync.d/ ]; then
	for f in /etc/portage/postsync.d/* ; do
		if [ -x \${f} ] ; then
			\${f}
		fi
	done
else
	:
fi
__EOF__

	chmod 755 "${D}"/etc/portage/bin/post_sync

	dodir /etc/portage/postsync.d
	echo '[ -x /usr/bin/q ] && /usr/bin/q -qr' > "${D}"/etc/portage/postsync.d/q-reinitialize
	if [ -x ${ROOT}/etc/portage/postsync.d/q-reinitialize ] ; then
		einfo "q-reinitialize already made executable by user; keeping permissions..."
		chmod 755 "${D}"/etc/portage/postsync.d/q-reinitialize
	fi
	
	dodir /etc/env.d
	if has_version ">=sys-apps/portage-2.1.2_pre1" ; then
		echo 'CONFIG_PROTECT_MASK="/etc/portage/bin/post_sync /etc/portage/postsync.d/q-reinitialize"' \
		> "${D}"/etc/env.d/99portage-utils
	else
		echo 'CONFIG_PROTECT_MASK="/etc/portage/bin /etc/portage/postsync.d"' > "${D}"/etc/env.d/99portage-utils
	fi
}

pkg_postinst() {
		elog "${ROOT}/etc/portage/postsync.d/q-reinitialize has been installed for convenience"
		elog "If you wish for it to be automatically run at the end of every --sync"
		elog "simply chmod +x ${ROOT}/etc/portage/postsync.d/q-reinitialize"
		elog "Normally this should only take a few seconds to run but file systems such as ext3 can take a lot longer."
		elog "If ever you find this to be an inconvenience simply chmod -x ${ROOT}/etc/portage/postsync.d/q-reinitialize"
}