zeldasoe-0.3.ebuild

zeldasoe-0.3.ebuild (text/plain), 1.06 KB, created by Tupone Alfredo on 2007-01-02 06:43:29 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PN="ZeldaSoE"
MY_P=${MY_PN}-${PV}

DESCRIPTION="Secret of Eternia"
HOMEPAGE="http://www.game-cade.com/zeldasoe.php"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND=">=dev-games/clanlib-0.7.8
	>=dev-lang/lua-5.0.2"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	rm ZeldaSoe.*
	epatch "${FILESDIR}/${P}"-gentoo.patch
	sed -i \
		-e "s:@GENTOO_DATA@:${GAMES_DATADIR}/${PN}:g" \
		src/zelda.cpp \
		zelda.xml \
		luasrc/objectdefinition.lua || die "sed, changing path, failed"
}

src_compile() {
	cd src
	emake || die "emake failed"
}

src_install() {
	dogamesbin src/${MY_PN} || die "installing the binary failed"
	dodoc README docs/README.* docs/ToDo
	dohtml -r docs/*.html docs/media
	insinto "${GAMES_DATADIR}/${PN}"
	doins -r zelda.xml images maps sounds luasrc \
		|| die 'Failed to install data files.'

	make_desktop_entry ${MY_PN} ${MY_PN}
	prepgamesdirs
}