ssam2-1_beta21.ebuild

ssam2-1_beta21.ebuild (text/plain), 3.67 KB, created by Maxim Konyushikhin on 2006-12-19 14:55:01 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

SZ="ftp://ftp.planetmirror.com/pub/seriouszone/serioussam2"
SZ2="http://public.planetmirror.com/pub/seriouszone/general/misc"
GAME_FILE="ss_linuxbeta_rc_2_1_public.tar.gz"
DOC_FILE="sed2_help.tar.gz"

DESCRIPTION="Serious Sam 2 and Serious Editor 2"
HOMEPAGE="http://www.serioussam2.com/
	http://www.croteam.com/
	http://www.seriouszone.com/"
SRC_URI="${SZ}/official/linux/${GAME_FILE}
	${SZ2}/${GAME_FILE}
	doc? (
		${SZ}/official/linux/${DOC_FILE}
		${SZ2}/${DOC_FILE} )"
#	maps? (
#		${SZ}/maps/militarydecay.zip
#		${SZ}/maps/alpineii.zip
#		${SZ}/maps/otmosis.zip )
#	models? (
#		${SZ}/models/SeriousSamantha.zip
#		${SZ}/models/ronaldmcdonald.zip
#		${SZ}/models/smoothsam.zip
#		${SZ}/models/sleepysam.zip
#		${SZ}/models/adventurousash.zip )"

# not sure about the license
LICENSE="LOKI-EULA"
SLOT="0"
KEYWORDS="~x86"
RESTRICT="mirror strip"
IUSE="doc"
#IUSE="doc maps models"

RDEPEND="virtual/opengl
	media-libs/openal"
DEPEND=""
#DEPEND="maps? ( app-arch/unzip )
#	models? ( app-arch/unzip )"

S=${WORKDIR}

pkg_setup() {
	games_pkg_setup

	cdrom_get_cds "Disk1"
}

src_unpack() {
	unpack "${GAME_FILE}"

	if use doc ; then
		unpack "${DOC_FILE}"
	fi

#	local f
#	if use maps ; then
#		for f in otmosis alpineii militarydecay ; do
#			unpack "${f}.zip"
#		done
#	fi

#	if use models ; then
#		for f in adventurousash sleepysam smoothsam ronaldmcdonald SeriousSamantha ; do
#			unpack "${f}.zip"
#		done
#	fi
}

src_install() {
	local dir=${GAMES_PREFIX_OPT}/${PN}
	local n
	local f
	local p

	einfo "Copying from ${CDROM_ROOT}"
	insinto "${dir}"

	# this is valid for files located on one DVD disk
	for n in 1 2 3 4 5 ; do
		for f in All_PC_01.gro All_PC_02.gro All_PC_03.gro \
			Disk1.txt Disk2.txt Disk3.txt Disk4.txt Disk5.txt \
			Movies_PC_01.gro Movies_PC_02.gro ; do
			p="${CDROM_ROOT}/Disk${n}/${f}"
			[ -f "${p}" ] && { doins "${p}" || die "Copying of ${p} failed"; }
		done

		for f in Bin Content; do
			p="${CDROM_ROOT}/Disk${n}/${f}"
			[ -d "${p}" ] && { doins -r "${p}" || die "Copying of ${p} failed"; }
		done
	done

	# check that critical files are copyed
	for f in All_PC_01.gro All_PC_02.gro All_PC_03.gro \
		Movies_PC_01.gro Movies_PC_02.gro ; do
		[ -f "${D}/${dir}/${f}" ] || die "Required file ${f} not found"
	done
	for f in Bin Content; do
		[ -d "${D}/${dir}/${f}" ] || die "Required directory ${f} not found"
	done

	if use doc ; then
		doins -r SeriousEngineTools_Help || die "Copying of help files failed"
	fi

#	if use maps || use models ; then
#		doins *.gro || die
#	fi

#	if use models ; then
#		doins -r Models || die
#	fi

	exeinto "${dir}"
	doexe RunEditor RunSam2 || die
	exeinto "${dir}"/Bin/Linux-Dynamic-Release
	doexe Bin/Linux-Dynamic-Release/{DedicatedServer,Sam2,SeriousEditor2,*.so} || die
	rm -f Bin/Linux-Dynamic-Release/{DedicatedServer,Sam2,SeriousEditor2,*.so}

	doins -r Bin Content || die
	doins README || die

	# Remove useless Windows files
	rm -rf "${D}/${dir}/Bin"/{*.exe,*.dll,*.DLL}

#	newicon ssam.xpm ${PN}.xpm || die
	games_make_wrapper ${PN} ./RunSam2 "${dir}" "${dir}"
	games_make_wrapper seditor2 ./RunEditor2 "${dir}" "${dir}"
#	make_desktop_entry ${PN} "Serious Sam 2" ${PN}.xpm
#	make_desktop_entry seditor2 "Serious Editor 2" seditor2.xpm

	# Ensure that file datestamps from the CD are sane
	find "${D}/${dir}" -exec touch '{}' \;

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "Security warnings should be ignored"
	echo
	elog "Please view README file for info about known limitations"
	elog "Important information about the Linux port is at:"
	elog "   http://forums.seriouszone.com/showthread.php?t=49869"
	echo
}