gajim-0.11.ebuild

gajim-0.11.ebuild (text/plain), 2.66 KB, created by Fab on 2006-12-19 14:27:17 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils virtualx multilib

DESCRIPTION="Jabber client written in PyGTK"
HOMEPAGE="http://www.gajim.org/"
SRC_URI="http://www.gajim.org/downloads/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="dbus gnome libnotify network nls remote spell srv zeroconf"

RDEPEND=">=dev-lang/python-2.4
	!<=dev-python/gnome-python-2
	>=dev-python/pygtk-2.6
	>=dev-python/pysqlite-2.0.5
	dbus? (
		>=sys-apps/dbus-0.60
		|| (
			dev-python/dbus-python
			(
				<sys-apps/dbus-0.90
				>=sys-apps/dbus-0.60
			)
		)
		|| (
			dev-libs/dbus-glib
			(
				<sys-apps/dbus-0.90
				>=sys-apps/dbus-0.60
			)
		)
	)
	gnome? ( >=dev-python/gnome-python-extras-2.10 )
	libnotify? ( x11-misc/notification-daemon )
	network? ( net-misc/networkmanager )
	srv? ( net-dns/bind-tools )
	zeroconf? ( net-dns/avahi )"

DEPEND="sys-devel/gettext
	dev-libs/glib
	>=dev-util/intltool-0.35.0
	>=dev-util/pkgconfig-0.19
	!gnome? ( spell? ( >=app-text/gtkspell-2.0.11 ) )
	x11-libs/libXScrnSaver"

pkg_setup() {
	if ! use dbus ; then
		
		use remote && eerror "dbus useflag is required by remote control."
		use libnotify && eerror "dbus useflag is required by libnotify."
		use zeroconf && eerror "dbus useflag is required by zeroconf."

		if use remote || use libnotify || use zeroconf ; then
			die "Please enable dbus USE flag for ${PN}."
		fi

	else
		
		# with dbus >= 0.90, dbus bindings are split out into seperate packages
		if has_version "<sys-apps/dbus-0.90"; then
			if ! built_with_use sys-apps/dbus python ; then
				eerror "Please rebuild sys-apps/dbus with \"python\" USE flag"
				die "Missing USE flag detected for sys-apps/dbus"
			fi
		fi

		if use zeroconf ; then
			einfo "Checking for required avahi features ..."
			if ! built_with_use net-dns/avahi dbus gtk python ; then
				eerror "To have zeroconf support in ${PN}, net-dns/avahi needs to be"
				eerror "re-built with the following USE flags enabled :"
				eerror "	dbus gtk python"
				die "Missing USE flags detected for net-dns/avahi"
			fi
		fi

	fi
}

src_compile() {
	cd ${S}

	local myconf="--enable-idle"
	
	if ! use gnome ; then
		myconf="${myconf} --enable-trayicon $(use_enable spell gtkspell)"
	else
		myconf="${myconf} --disable-trayicon --disable-gtkspell"
	fi
	
	Xeconf \
		$(use_enable nls) \
		$(use_enable remote) \
		${myconf} \
		--docdir=/usr/share/doc/${PF} || die "Xeconf failed"
	
	Xemake || die "Xemake failed"
}

src_install() {
	Xemake PREFIX=/usr DESTDIR=${D} LIBDIR=/$(get_libdir) install || \
		die "Xemake install failed"
	
	rm ${D}/usr/share/doc/${PF}/README.html
	dohtml README.html
}