# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils versionator

DESCRIPTION="Open Source Jabber Server"
HOMEPAGE="http://ftp.xiaoka.com/jabberd2/"
SRC_URI="http://ftp.xiaoka.com/jabberd2/releases/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="berkdb debug memdebug idn ipv6 ldap mysql pam pipe postgres sqlite ssl"

DEPEND=">=net-im/jabber-base-0.01
	dev-libs/cyrus-sasl
	dev-libs/expat
	ssl? ( >=dev-libs/openssl-0.9.6b )
	idn? ( >=net-dns/libidn-0.3.0 )
	ldap? ( >=net-nds/openldap-2.1.0 )
	berkdb? ( >=sys-libs/db-4.1.24 )
	mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql )
	sqlite? ( >=dev-db/sqlite-3.0 )
	=sys-devel/automake-1.10"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-configure.in.patch"
	eautoreconf
}

src_compile() {

	local localconf=
	if use debug; then
		localconf="${localconf} --enable-debug"
		use memdebug && localconf="${localconf} --enable-nad-debug --enable-pool-debug"
	else
		if use memdebug; then
			ewarn
			ewarn '"memdebug" requires "debug" enabled.'
			ewarn
		fi
	fi

	econf \
		--localstatedir=/var \
		--sysconfdir=/etc/jabber \
		${localconf} \
		$(use_enable berkdb db) \
		$(use_enable idn) \
		$(use_enable ipv6) \
		$(use_enable ldap) \
		$(use_enable mysql) \
		$(use_enable pam) \
		$(use_enable pipe) \
		$(use_enable postgres pgsql) \
		$(use_enable sqlite) \
		$(use_enable ssl) \
		|| die "econf failed"
	emake || die "make failed"

}

src_install() {

	make DESTDIR="${D}" install || die "make install failed"

	fowners jabber:jabber /usr/bin/{jabberd,router,resolver,sm,c2s,s2s}
	fperms 750 /usr/bin/{jabberd,router,resolver,sm,c2s,s2s}

	newinitd "${FILESDIR}/jabberd-${PV}.init" jabberd || die "newinitd failed"

	dodoc AUTHORS PROTOCOL README
	docinto tools
	for i in db-setup.{mysql,pgsql,sqlite} db-update.mysql db-setup-status.mysql migrate.pl pipe-auth.pl
	do
		dodoc tools/${i}
	done

	cd "${D}/etc/jabber/"
	sed -i \
		-e 's,/var/jabberd/pid/,/var/run/jabber/,g' \
		-e 's,/var/jabberd/log/,/var/log/jabber/,g' \
		-e 's,/var/jabberd/db,/var/spool/jabber/,g' \
		*.xml.dist *.xml || die "sed failed"
}