# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

HISTORY_PV="1_10b"
CONTROLS_PV="0.106.2"

DESCRIPTION="textual front-end for M.A.M.E."
HOMEPAGE="http://www.anti-particle.com/wahcade.shtml"
SRC_URI="http://www.anti-particle.com/projects/${PN}/${P}.tar.gz
	http://www.catver.com/catveren.zip
	http://www.arcade-history.com/download/history${HISTORY_PV}.zip
	http://fe.donkeyfly.com/controls/dat/ini/controls.ini.${CONTROLS_PV}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND=">=dev-lang/python-2.4
	>=dev-python/pygtk-2.6"
DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# The COPYING doc file is kept because it is shown by "About..."
	rm build_deb_package doc/INSTALL

	# Move to convenient directory
	mkdir setup
	mv -f "${WORKDIR}"/*.{dat,ini} setup
	mv -f setup/{C,c}atver.ini
}

src_install() {
	local dir=${GAMES_DATADIR}/${PN}

	insinto "${dir}"
	doins -r * || die
	rm -rf "${D}/${dir}"/{doc,install,*.desktop}
	insinto "${dir}/doc"
	doins doc/COPYING || die

	local f
	for f in "" -{history-viewer,setup} ; do
		games_make_wrapper "${PN}${f}" "python ${PN}${f}" "${dir}"
	done
	doicon pixmaps/${PN}.png || die
	make_desktop_entry ${PN} "Wah!Cade" ${PN}.png

	dodoc "${WORKDIR}"/*.txt doc/*

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "Follow the setup instructions at:"
	elog "   http://www.anti-particle.com/wahcade_quick.shtml"
	elog
	elog "The history, catver and controls files are in:"
	elog "   ${GAMES_DATADIR}/${PN}/setup"
	echo
}