# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils multilib toolchain-funcs

MY_P="${P}DrGonzo"

DESCRIPTION="Redesign of the XMMS music player (server only)"
HOMEPAGE="http://wiki.xmms2.xmms.se/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

# See COPYING file for license
LICENSE="GPL-2
	LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aac alsa avahi curl daap ecore flac gnome icecast id3 jack java mms modplug mp3 oss musepack python ruby samba sid speex vorbis wma"

S=${WORKDIR}/${MY_P}

RDEPEND=">=dev-libs/glib-2.6.0
	>=dev-db/sqlite-3.2.6
	dev-libs/boost
	aac? ( >=media-libs/faad2-2.0 )
	alsa? ( media-libs/alsa-lib )
	curl? ( >=net-misc/curl-7.11.2 )
	ecore? ( x11-libs/ecore )
	ruby? ( dev-lang/ruby )
	java? ( virtual/jdk )
	samba? ( net-fs/samba )
	python? ( >=dev-lang/python-2.3
		>=dev-python/pyrex-0.9.3 )
	modplug? ( media-libs/libmodplug )
	musepack? ( >=media-libs/libmusepack-1.1 )
	vorbis? ( media-libs/libvorbis
		media-libs/libogg )
	flac? ( media-libs/libvorbis
		>=media-libs/flac-1.1.2 )
	jack? ( >=media-sound/jack-0.100.0 )
	mp3? ( media-libs/libmad )
	speex? ( >=media-libs/libogg-1.1
		media-libs/speex )
	daap? ( >=media-libs/libopendaap-0.3.0 )
	avahi? ( >=net-dns/avahi-0.6 )
	gnome? ( >=gnome-base/gnome-vfs-2.0 )
	sid? ( media-sound/sidplay media-libs/resid )
	wma? ( media-video/ffmpeg )
	mms? ( media-libs/libmms )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=dev-lang/python-2.3
	>=dev-util/scons-0.96.1"

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i \
		-e "s:/lib:/$(get_libdir):g" \
		SConstruct xmms2.pc.in xmmsenv.py || die "sed failed"
}

src_compile() {
	local exclude u o
	for u in aac:faad alsa curl ecore gnome:gnomevfs modplug flac \
		jack mp3:mad musepack oss ruby samba sid speex  \
		vorbis daap id3:id3v2 avahi:mdns java wma mms \
		python icecast:icymetaint ; do
		o=${u##*:} ; o=${o:-${u}}
		u=${u%%:*}
		use ${u} || exclude="${exclude} ${o}"
	done
	einfo "Excluding: ${exclude}"

	scons \
		CC="$(tc-getCC)" \
		CXX="$(tc-getCXX)" \
		CCFLAGS="${CFLAGS}" \
		CXXFLAGS="${CXXFLAGS}" \
		LINK="$(tc-getCC)" \
		PREFIX="/usr" \
		MANDIR="/usr/share/man" \
		INSTALLDIR="${D}" \
		CONFIG="yes" \
		EXCLUDE="${exclude}" \
		|| die "Scons failed"
}

src_install() {
	scons install || die "scons install failed"

	# Including COPYING due to multi-licensing
	dodoc AUTHORS ChangeLog COPYING README TODO
}