gxmms2-0.6.4.ebuild

gxmms2-0.6.4.ebuild (text/plain), 1.21 KB, created by Paul Bredbury on 2006-11-16 00:43:51 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="XMMS2 client using GTK+ 2.6"
HOMEPAGE="http://wejp.k.vu/projects/xmms2/"
SRC_URI="http://wejp.k.vu/projects/xmms2/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="gkrellm"

RDEPEND=">=media-sound/xmms2-0.2
	>=x11-libs/gtk+-2.6
	gkrellm? ( >=app-admin/gkrellm-2.2 )"
DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Makefile suggests -O2
	filter-flags -Os -O1 -O3

	# Don't use /usr/local
	sed -i \
		-e 's:\(PREFIX=\).*:\1${D}/usr:' \
		Makefile || die "sed Makefile failed"
}

src_compile() {
	local target=${PN}
	use gkrellm && target="${PN} gkrellxmms2"

	emake \
		MY_CC="$(tc-getCC)" \
		MY_CFLAGS="${CFLAGS}" \
		MY_LDFLAGS="${LDFLAGS}" \
		${target} \
		|| die "emake failed"
}

src_install() {
	emake install_${PN} || die "emake install_${PN} failed"

	if use gkrellm ; then
		emake install_gkrellxmms2 || die "emake install_gkrellxmms2 failed"
		dodoc README.gkrellxmms2
	fi

	newicon ${PN}src/${PN}_mini.xpm ${PN}.xpm || die "newicon failed"
	make_desktop_entry ${PN} ${PN} ${PN}.xpm

	dodoc CHANGELOG README README.${PN}
}