# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PV=${PV//./-}
MY_PV=${MY_PV//_/}

DESCRIPTION="Object-oriented Graphics Rendering Engine"
HOMEPAGE="http://www.ogre3d.org/"
SRC_URI="mirror://sourceforge/ogre/${PN}-linux_osx-v${MY_PV}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="cegui cg debug devil doc double-precision examples gtk openexr sdl threads"

RDEPEND=">=dev-libs/zziplib-0.13.36
	>=media-libs/freetype-2.1.10
	threads? ( >=dev-libs/boost-1.33.0 )
	cegui? ( >=dev-games/cegui-0.4.0 )
	devil?	( >=media-libs/devil-1.6.7 )
	openexr? ( >=media-libs/openexr-1.2 )
	sdl? ( >=media-libs/libsdl-1.2.8 )
	virtual/opengl
	x11-libs/libXaw x11-libs/libXrandr x11-libs/libXt x11-libs/libX11
	sys-libs/zlib"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/flex
	cg? ( >=media-gfx/nvidia-cg-toolkit-1.2 )"

S=${WORKDIR}/ogrenew
RESTRICT="debug? ( strip )"

pkg_setup() {
	if has_version '<dev-games/ogre-1.2.0' ; then
		eerror "***************************************************************"
		eerror "* Before installing new version (or reinstall current one) of *"
		eerror "* dev-games/ogre You need to uninstall currently existing in  *"
		eerror '* system. Type "emerge -C dev-games/ogre" to do it now.       *'
		eerror "***************************************************************"
		die "ogre already installed"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/ogre-1.2.1-config-disable-samples.patch

	einfo Running boostrap
	./bootstrap || die "bootstrap failed"
}

src_compile() {
	local mycfgtk="cli"
	use gtk && mycfgtk="gtk"

	local myplat="GLX"
	use sdl && myplat="SDL"

	econf \
		--with-cfgtk=${mycfgtk} \
		--with-platform=${myplat} \
		$(use_enable devil) \
		$(use_enable cg) \
		$(use_enable openexr) \
		$(use_enable threads threading) \
		$(use_enable double-precision double) \
		$(use_enable debug) \
		$(use_enable examples samples) \
		|| die
	emake || die "emake failed"
}

src_install() {
	einstall || die "install failed"
	insinto /usr/share/OGRE/Media
	doins -r Samples/Media/*
	if use examples ; then
		into /usr/share/OGRE/Samples/
		dobin Samples/Common/bin/*
		insinto /usr/share/OGRE/Samples/bin/
		echo "" > Samples/Common/bin/ogre.cfg
		sed -e 's,/usr/local,/usr,g' Samples/Common/bin/plugins.cfg >plugins.cfg.tmp
		mv plugins.cfg.tmp Samples/Common/bin/plugins.cfg
		insopts -m644
		doins Samples/Common/bin/*.cfg
		insopts -m666
		doins Samples/Common/bin/ogre.cfg
		rm -f "${D}/usr/share/OGRE/Samples/bin"/*.in
		rm -f "${D}/usr/share/OGRE/Samples/bin"/Makefile*
		find "${D}/usr/share/OGRE/Samples/" -type d -name CVS -exec rm -rf {} \; >/dev/null 2>&1
	fi
	dodoc AUTHORS BUGS LINUX.DEV README Docs/README.linux
	if use doc ; then
		dohtml -r Docs 
	else
		dohtml -r Docs/manual
	fi
}