jpeg-6b-r8.ebuild

jpeg-6b-r8.ebuild (text/plain), 1.52 KB, created by INODE64 Sistemas on 2006-11-13 14:19:36 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/jpeg/jpeg-6b-r7.ebuild,v 1.15 2006/09/04 03:59:21 kumba Exp $

inherit libtool eutils toolchain-funcs

PATCH_VER=1.4
DESCRIPTION="Library to load, handle and manipulate images in the JPEG format"
HOMEPAGE="http://www.ijg.org/"
SRC_URI="http://cetus.sakura.ne.jp/softlab/jpeg-x86simd/sources/jpegsrc-6b-x86simd-1.02.tar.bz2
        mirror://gentoo/${P}-patches-${PATCH_VER}.tar.bz2"

LICENSE="as-is"
SLOT="0"
KEYWORDS="x86 ~x86-fbsd"
IUSE=""

RDEPEND=""
DEPEND="${RDEPEND}
	dev-lang/nasm
	>=sys-devel/libtool-1.5.10-r4"

S=${WORKDIR}/jpeg-6bx

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/makefile.diff
	epatch "${WORKDIR}"/patch/07_all_jpeg-LANG.patch
	epatch "${WORKDIR}"/patch/30_all_jpeg-crop.patch
	epatch "${WORKDIR}"/patch/50_all_jpeg-Debian-rdjpgcom_locale.patch
	epatch "${WORKDIR}"/patch/52_all_jpeg-Debian-rdppm.patch
	epatch "${WORKDIR}"/patch/60_all_jpeg-maxmem-sysconf.patch

	elibtoolize
}

src_compile() {
	tc-export CC RANLIB AR

	econf --enable-shared --enable-static \
		--enable-maxmem=64 || die "econf failed"
	emake || die "make failed"
	emake -C "${WORKDIR}"/extra || die "make extra failed"
}

src_install() {
	make install DESTDIR="${D}" || die "install"
	make -C "${WORKDIR}"/extra install DESTDIR="${D}" || die "install extra"

	dodoc README install.doc usage.doc wizard.doc change.log \
		libjpeg.doc example.c structure.doc filelist.doc \
		coderules.doc
}