# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P=SlimServer_v${PV}
DESCRIPTION="Slim Devices' SlimServer"
HOMEPAGE="http://www.slimdevices.com/slimserver/"
SRC_URI="http://www.slimdevices.com/downloads/${MY_P}/${MY_P}.no-cpan-arch.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="aac alac encode ffmpeg flac ogg musepack shorten"
DEPEND="sys-apps/findutils"
RDEPEND="
	>=dev-lang/perl-5.8.3
	>=dev-db/mysql-5
	>=dev-perl/Compress-Zlib-1.41
	>=dev-perl/DBD-mysql-3.0002
	>=dev-perl/DBI-1.50
	>=dev-perl/Digest-SHA1-2.11
	dev-perl/GD
	>=dev-perl/HTML-Parser-3.48
	>=dev-perl/Template-Toolkit-2.14
	>=dev-perl/XML-Parser-2.34
	>=dev-perl/YAML-Syck-0.64
	>=net-misc/mDNSResponder-107
	>=virtual/perl-Time-HiRes-1.86
	aac? ( media-libs/faad2 )
	alac? ( media-sound/alac_decoder )
	encode? ( media-sound/lame )
	ffmpeg? ( media-video/ffmpeg )
	flac? ( media-libs/flac )
	ogg? ( media-sound/sox )
	musepack? ( media-sound/musepack-tools )
	shorten? ( media-sound/shorten )
	"
S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if use ogg; then
		built_with_use media-sound/sox ogg || die "media-sound/sox not built with USE=ogg"
	fi
	enewgroup slimserver || die
	enewuser slimserver -1 -1 /opt/slimserver slimserver || die
}

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/slimserver-mDNSResponderPosix-107.patch
	epatch ${FILESDIR}/slimserver-bootstrap-gentoo.patch
	rm Bin/build-perl-modules.pl
	rm CPAN/YAML/Syck.pm
	rm MySQL/errmsg.{sys,txt}
}

src_install() {
	# copy all files
	mkdir -p ${D}/opt/slimserver
	cp -r * ${D}/opt/slimserver
	# initialize preferences file
	mkdir -p ${D}/etc
	touch ${D}/etc/slimserver.prefs
	fowners slimserver:slimserver /etc/slimserver.prefs
	# create symbolic links to local mysql files
	dosym ../../../usr/sbin/mysqld /opt/slimserver/Bin/mysqld
	dosym ../../../usr/share/mysql/english/errmsg.sys \
		/opt/slimserver/MySQL/errmsg.sys
	dosym ../../../usr/share/mysql/errmsg.txt \
		/opt/slimserver/MySQL/errmsg.txt
	# create symbolic link to local mDNSResponderPosix
	dosym ../../../usr/sbin/mDNSResponderPosix \
		/opt/slimserver/Bin/mDNSResponderPosix
	# install init scripts
	newconfd ${FILESDIR}/slimserver.conf.d slimserver
	newinitd ${FILESDIR}/slimserver.init.d slimserver
	# initialize /var/{cache,run}
	mkdir -p ${D}/var/{cache,run}/slimserver
	keepdir /var/{cache,run}/slimserver
	fowners slimserver:slimserver /var/{cache,run}/slimserver
	# initialize /var/log
	mkdir -p ${D}/var/log
	touch ${D}/var/log/slimserver
	fowners slimserver:slimserver /var/log/slimserver
}