Modified Ebuild

libsoundtouch-1.3.1.ebuild (text/plain), 1.23 KB, created by Sok Ann Yap on 2006-10-29 01:15:36 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libsoundtouch/libsoundtouch-1.3.1.ebuild,v 1.2 2006/10/04 15:56:33 flameeyes Exp $

inherit autotools toolchain-funcs

IUSE="static sse"

MY_P="${P/lib}"

DESCRIPTION="Audio processing library for changing tempo, pitch and playback rates."
HOMEPAGE="http://www.surina.net/soundtouch/"
SRC_URI="http://www.surina.net/soundtouch/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~ppc-macos"

RDEPEND="virtual/libc"
DEPEND="app-arch/unzip"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	if [[ $(tc-arch) == "x86" ]] && ! use sse; then
		epatch "${FILESDIR}"/disable-optimization.patch
	fi
	epatch "${FILESDIR}"/${PV}-respect-cflags.patch
	eautoreconf
}

src_compile() {
	econf $myconf \
		$(use_enable static) \
		--disable-integer-samples \
		--with-pic || die "./configure failed"
	# fixes C(XX)FLAGS from configure, so we can use *ours*
	emake CFLAGS="$CFLAGS" CXXFLAGS="$CXXFLAGS" || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" pkgdocdir="/usr/share/doc/${PF}" install || die
	rm -f ${D}/usr/share/doc/${PF}/COPYING.TXT	# remove obsolete LICENCE file
}