Update to 0.37_beta

astromenace-bin-0.37_beta.ebuild (text/plain), 1.59 KB, created by jovie1024 on 2006-10-23 18:33:56 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator games

MY_PN=${PN%-bin}
MY_PV=$(delete_all_version_separators)
MY_PV=${MY_PV/beta/b}

DESCRIPTION="Modern 3D space shooter with spaceship upgrade possibilities"
HOMEPAGE="http://www.viewizard.com/astromenace/index_linux.php"
SRC_URI="http://www.viewizard.com/download/amenace${MY_PV}.tar.bz2"

# See License.txt
LICENSE="astromenace"
KEYWORDS="~amd64 ~x86"
IUSE=""
SLOT="0"
RESTRICT="strip"

# libvorbis provides libvorbisfile.so
# Used to depend on >=media-libs/sdl-mixer-1.2.6, now openal and alut
RDEPEND="
	virtual/glu
	virtual/opengl
	>=media-libs/freealut-1.0.1
	x86? (
		>=media-libs/jpeg-6b
		x11-libs/libX11
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libXext
		x11-libs/libXrandr
		x11-libs/libXrender
		media-libs/libmikmod
		>=media-libs/openal-0.0.8
		>=media-libs/sdl-image-1.2.4
		>=media-libs/libsdl-1.2.6
		>=media-libs/libogg-1.1
		>=media-libs/libvorbis-1.1
	)
	amd64? (
		>=app-emulation/emul-linux-x86-sdl-2.3
		app-emulation/emul-linux-x86-soundlibs
		app-emulation/emul-linux-x86-xlibs
		app-emulation/emul-linux-x86-baselibs
	)"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_PN}

src_install() {
	local dir=${GAMES_PREFIX_OPT}/${MY_PN}
	local exe="AstroMenace"

	insinto "${dir}"
	doins -r * || die "doins failed"
	exeinto "${dir}"
	doexe "${exe}" || die "doexe failed"

	games_make_wrapper ${MY_PN} "./${exe}" "${dir}"

	newicon ${MY_PN}_128.png ${MY_PN}.png || die "newicon failed"
	make_desktop_entry ${MY_PN} "Astro Menace" ${MY_PN}.png

	prepgamesdirs
}