campos-dacapo-2.7.7.ebuild

campos-dacapo-2.7.7.ebuild (text/plain), 1.65 KB, created by Donnie Berkholz (RETIRED) on 2006-10-16 23:07:06 UTC

# Copyright 2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/camp/CVSROOT/CamposEbuilds/portage/sci-calculators/campos-dacapo-python/campos-dacapo-python-0.6.ebuild,v 1.2 2006/02/15 10:27:52 schiotz Exp $

inherit distutils fortran multilib

MY_P=Dacapo-${PV}
DESCRIPTION="Dacapo is a plane-wave based Density Functional Theory program"
HOMEPAGE="http://www.camp.dtu.dk/campos/Dacapo"
SRC_URI="http://dcwww.camp.dtu.dk/campos/download/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RDEPEND=">=sci-physics/campos-ase-0.11
	virtual/blas
	=sci-libs/fftw-2*
	sci-libs/netcdf"
DEPEND="${RDEPEND}"
S=${WORKDIR}/${MY_P}
FORTRAN="gfortran ifc"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e "s:FC=pgf90:FC=${FORTRANC}:g" \
		-e "s:FC90=pgf90:FC90=${FORTRANC}:g" \
		src/Makefile
}

src_compile() {
	pushd "${S}"/Python
	distutils_src_compile
	popd

	pushd "${S}"/src

	mkdir -p netcdf/include/generic
	cp ${ROOT}usr/$(get_libdir)/libnetcdf.a netcdf/include/generic/

	case ${FORTRANC} in
		gfortran) TARGET="generic" ;;
		ifc) TARGET="intellinux" ;;
	esac

	# We don't attempt to do the MPI build yet, it requires a lot of hacking
	# in src/Makefile. Build defaults to serial, see MP in src/Makefile
	emake \
		${TARGET} \
		GENERIC_OPT="${FFLAGS}" \
		INTELLINUX_OPT="${FFLAGS}" \
		|| die "emake generic failed"

	popd
}

src_install() {
	pushd "${S}"/Python
	distutils_src_install
	popd

	insinto /usr/share/dacapo/psp
	doins psp/*/*/*.pseudo

	echo "DACAPOPATH=${ROOT}usr/share/dacapo/psp" > "${T}"/55campos-dacapo
	doenvd "${T}"/55campos-dacapo

	dodoc dacapo.csh dacapo_ser+paral_wrapper.run dacapo.sh
}