media-sound/ardour-2.0_beta4.ebuild

ardour-2.0_beta4.ebuild (text/plain), 1.83 KB, created by Marco Squarcina on 2006-10-09 11:03:44 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit eutils

DESCRIPTION="multi-track hard disk recording software"
HOMEPAGE="http://ardour.org/"
SRC_URI="http://ardour.org/files/releases/${P/_/}.tar.bz2"
RESTRICT="nomirror"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64 ~ppc"
IUSE="altivec audiounits coreaudio debug nls osc sse vst"

RDEPEND="osc? ( media-libs/liblo )
	>=media-libs/liblrdf-0.3.6
	>=media-libs/raptor-1.2.0
	>=media-sound/jack-audio-connection-kit-0.100.0
	>=dev-libs/glib-2.10.3
	>=x11-libs/gtk+-2.8.8
	>=media-libs/libsamplerate-0.1.1-r1
	>=dev-libs/libxml2-2.5.7
	>=media-libs/libart_lgpl-2.3.16
	>=media-libs/libsndfile-1.0.16
	dev-libs/boost 
	gnome-base/libgnomecanvas" 

DEPEND="${RDEPEND}
	sys-devel/libtool
	dev-util/pkgconfig
	>=dev-util/scons-0.96.1
	nls? ( sys-devel/gettext )"

S="${WORKDIR}/${P/_/}"

src_compile() {
	# Required for scons to "see" intermediate install location
	mkdir -p "${D}"

	local FPU_OPTIMIZATION=$((use altivec || use sse) && echo 1 || echo 0)
	local ARDOUR_DEBUG=$(use debug && echo 1 || echo 0)
	local NLS=$(use nls && echo 1 || echo 0)
	local COREAUDIO=$(use coreaudio && echo 1 || echo 0)
	local AUDIOUNITS=$(use audiounits && echo 1 || echo 0)
	local OSC=$(use osc && echo 1 || echo 0)
	local VST=$(use vst && echo 1 || echo 0)
	
	cd ${S}
	scons \
		DEBUG=${ARDOUR_DEBUG} \
		FPU_OPTIMIZATION=${FPU_OPTIMIZATION} \
		DESTDIR="${D}" \
		NLS=${NLS} \
		AUDIOUNITS=${AUDIOUNITS} \
		COREAUDIO=${COREAUDIO} \
		LIBLO=${OSC} \
		VST=${VST} \
		PREFIX=/usr || die "scons make failed"
}

src_install() {
	scons install || die "make install failed"

	dodoc DOCUMENTATION/*
}

pkg_postinst() {
	if use sse
	then
		einfo ""
		einfo "Start ardour with the -o argument to use the optimized SSE functions:"
		einfo ""
		einfo "	  ardour -o"
		einfo ""
	fi
}