centericq-4.21.0-r3.ebuild

centericq-4.21.0-r3.ebuild (text/plain), 3.12 KB, created by Stéphane Bisinger on 2006-09-24 11:15:35 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/centericq/centericq-4.21.0-r2.ebuild,v 1.7 2006/02/17 16:38:52 blubb Exp $

inherit eutils

IUSE="bidi nls ssl gnutls crypt icq jabber aim msn yahoo gg irc rss lj unicode"

DESCRIPTION="A ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
SRC_URI="http://thekonst.net/download/${P}.tar.bz2"
HOMEPAGE="http://thekonst.net/en/centericq"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"

DEPEND="virtual/libc
	>=sys-libs/ncurses-5.2
	bidi? ( dev-libs/fribidi )
	jabber? ( crypt? ( >=app-crypt/gpgme-1.0.2 ) )
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.0 )
		!gnutls?  ( >=dev-libs/openssl-0.9.6g )
	)
	msn? ( net-misc/curl )"

RDEPEND="${DEPEND}
	nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${A}
	cd ${S}

	use amd64 && epatch ${FILESDIR}/${PN}-amd64.patch

	# fix bug #100519
	epatch ${FILESDIR}/${P}-icq-short-read.diff
	epatch ${FILESDIR}/${P}-memory-handling.diff

	# fix bug #114038
	epatch ${FILESDIR}/${P}-ktools.diff

	#fix bug #131426
	epatch ${FILESDIR}/${P}-libmsn.diff

	# Add browser selection dialog
	epatch ${FILESDIR}/${P}-msg_esc.diff

	# fix jabber segmentation fault
	epatch ${FILESDIR}/${P}-jabber_segv.diff

	# link against ncursesw for fake unicode support
	use unicode && epatch ${FILESDIR}/${P}-utf8.diff
}

src_compile() {
	local myopts="--disable-konst"
	use nls && myopts="${myopts} --enable-locales-fix" || myopts="${myopts} --disable-nls"
	use bidi && myopts="${myopts} --with-fribidi"
	if use ssl && use gnutls ; then
		myopts="${myopts} --with-ssl --without-openssl"
	elif use ssl && ! use gnutls ; then
		myopts="${myopts} --with-ssl --with-openssl"
	else
		myopts="${myopts} --without-ssl"
	fi

	use icq || myopts="${myopts} --disable-icq"
	use jabber && {
		use crypt || myopts="${myopts} --without-gpgme"
	} || myopts="${myopts} --disable-jabber"
	use aim || myopts="${myopts} --disable-aim"
	use msn || myopts="${myopts} --disable-msn"
	if use msn && (! use ssl && ! use gnutls) ; then
		eerror ""
		eerror "USE flag problem"
		eerror "================"
		eerror "'msn' USE flag detected, but 'ssl' and 'gnutls' USE flag missing:"
		eerror "MSN support needs libcurl with SSL support."
		eerror ""
		die "Please either activate the 'ssl' or 'gnutls' USE flag or deactivate the 'msn' USE flag for net-im/centericq"
	fi
	use yahoo || myopts="${myopts} --disable-yahoo"
	use gg || myopts="${myopts} --disable-gg"
	use irc || myopts="${myopts} --disable-irc"
	use rss || myopts="${myopts} --disable-rss"
	use lj || myopts="${myopts} --disable-lj"

	# Re-run autconf and automake to keep from barfing. This is a hack.
	einfo "Running autoconf to fix configure scripts"
	for i in $(ls -1 {.,*-*}/configure.in); do
		IFS='/'; set -- ${i}; unset IFS; dir="${1}"
		einfo "-> dir: ${dir}"
		pushd ${dir} >/dev/null && WANT_AUTOCONF=2.5 autoconf && popd >/dev/null
	done

	econf ${myopts} || die "Configure failed"
	emake || die "Compilation failed"
}

src_install () {
	einstall || die "Installation failed"

	dodoc ABOUT-NLS AUTHORS ChangeLog COPYING FAQ README THANKS TODO
}