ultimatestunts-0.6.2.ebuild

ultimatestunts-0.6.2.ebuild (text/plain), 1.23 KB, created by Tristan Heaven (RETIRED) on 2006-09-18 13:16:56 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils versionator games

MY_P=${PN}-srcdata-$(replace_all_version_separators)1
DESCRIPTION="Remake of the famous Stunts game"
HOMEPAGE="http://www.ultimatestunts.nl/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="media-libs/libsdl
	media-libs/openal
	media-libs/freealut
	virtual/opengl
	virtual/glu
	x11-libs/libSM
	x11-libs/libICE
	x11-libs/libX11
	x11-libs/libXi
	x11-libs/libXext
	x11-libs/libXmu
	x11-libs/libXt"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch \
		"${FILESDIR}"/${P}-gcc41.patch \
		"${FILESDIR}"/${P}-freealut.patch \
		"${FILESDIR}"/${P}-paths.patch

	autopoint -f || die "autopoint failed"
	AT_M4DIR=m4 eautoreconf
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	make_desktop_entry ustunts "Ultimate Stunts"
	dodoc AUTHORS README

	rm -rf $(find "${D}" -name CVS)
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	echo
	ewarn "Please update or remove ~/.ultimatestunts/ultimatestunts.conf"
	ewarn "if you have it to update the path for the data files."
	echo
}