New ebuild

tremulous-1.1.0-r1.ebuild (text/plain), 3.85 KB, created by Martin Doucha on 2006-09-16 09:39:46 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/tremulous/tremulous-1.1.0.ebuild,v 1.1 2006/09/06 22:19:45 wolf31o2 Exp $

inherit eutils toolchain-funcs games

DESCRIPTION="Team-based aliens vs humans FPS with buildable structures"
HOMEPAGE="http://tremulous.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.zip
	http://0day.icculus.org/mirrors/${PN}/${P}.zip
	ftp://ftp.wireplay.co.uk/pub/quake3arena/mods/${PN}/${P}.zip
	mirror://gentoo/${PN}-src-${PV}.zip"

LICENSE="GPL-2
	CCPL-Attribution-ShareAlike-2.5"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated openal opengl tjw vorbis"

UIDEPEND="openal? ( media-libs/openal )
	media-libs/libsdl
	vorbis? (
		media-libs/libogg
		media-libs/libvorbis )
	virtual/opengl
	|| ( (
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"
RDEPEND="opengl? ( ${UIDEPEND} )
	!opengl? ( !dedicated? ( ${UIDEPEND} ) )
	!games-fps/tremulous-bin"
DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}/${PN}

pkg_setup() {
	games_pkg_setup

	if use amd64 ; then
		ewarn "emerge games-fps/tremulous-bin instead for better performance."
		echo
	fi
}

src_unpack() {
	unpack ${A}
	cd ${PN}

	if ! ( use dedicated || use tjw ) || use opengl ; then
		unpack ./${P}-src.tar.gz
		mv ${P}-src ${P}-client
		cd ${P}-client

		# backport client patch
		epatch "${S}/${PN}-svn755.patch"
		cd ..
	fi

	if use dedicated || use tjw; then
		unpack ./${P}-src.tar.gz
		mv ${P}-src ${P}-server
		cd ${P}-server

		# SVN823 server
		epatch "${S}/${PN}-svn755-823.patch"

		if use tjw ; then
			# SVN823 TJW server
			epatch "${S}/${PN}-svn823.patch"
		fi
	fi
}

src_compile() {
	buildit() { use $1 && echo 1 || echo 0 ; }

	local build_client=1
	if use dedicated && ! use opengl ; then
		build_client=0
	fi

	local build_server=0
	if use dedicated || use tjw ; then
		build_server=1
	fi

	# build backport client
	if [ ${build_client} -ne 0 ] ; then
		cd ${P}-client
		emake \
			BUILD_CLIENT=1 \
			BUILD_SERVER=0 \
			BUILD_GAME_SO=0 \
			BUILD_GAME_QVM=0 \
			CC="$(tc-getCC)" \
			DEFAULT_BASEDIR="${GAMES_DATADIR}/${PN}" \
			USE_CODEC_VORBIS=$(buildit vorbis) \
			USE_OPENAL=$(buildit openal) \
			USE_LOCAL_HEADERS=0 \
			OPTIMIZE= \
			|| die "emake client failed"
		cd ..
	fi

	# build SVN823/TJW server
	if use dedicated || use tjw; then
		cd ${P}-server
		emake \
			BUILD_CLIENT=0 \
			BUILD_SERVER=${build_server} \
			BUILD_GAME_QVM=1 \
			CC="$(tc-getCC)" \
			DEFAULT_BASEDIR="${GAMES_DATADIR}/${PN}" \
			USE_LOCAL_HEADERS=0 \
			OPTIMIZE= \
			|| die "emake server failed"
		cd ..
		mkdir base2
		mkdir base2/vm
		cp ${P}-server/build/release-linux-${ARCH}/base/vm/game.qvm base2/vm/
	fi
}

src_install() {
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r base || die "doins -r failed"

	dodoc ChangeLog manual.pdf

	local bindir=build/release-linux-${ARCH}

	if use opengl || ! use dedicated ; then
		newgamesbin ${P}-client/${bindir}/${PN}.${ARCH} ${PN} \
			|| die "newgamesbin client failed"
		doicon misc/${PN}.xpm
		make_desktop_entry ${PN} Tremulous ${PN}.xpm
	fi

	if use dedicated || use tjw ; then
		doins -r base2 || die "doins -r failed"
		newgamesbin ${P}-server/${bindir}/tremded.${ARCH} ${PN}-ded \
			|| die "newgamesbin ded failed"
	fi

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	if use opengl || ! use dedicated ; then
		ewarn "Tremulous client should not be used to host a game server."
		if use dedicated || use tjw ; then
			ewarn "You should use ${PN}-ded instead."
		else
			ewarn "You should re-emerge Tremulous with USE=\"dedicated\""
			ewarn "or USE=\"tjw\" and then use ${PN}-ded instead."
		fi
		echo
	fi

	if use dedicated || use tjw ; then
		einfo "To start a dedicated server, run '${PN}-ded +set fs_game base2'"
		echo
	fi

	elog "Read instructions:  http://tremulous.net/manual/"
	elog "or:  ${dir}/manual.pdf"
	echo
}