xanim-export-2.80.1-r4.ebuild

xanim-export-2.80.1-r4.ebuild (text/plain), 3.63 KB, created by Jakub Moc (RETIRED) on 2006-08-24 10:39:15 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit flag-o-matic eutils toolchain-funcs
strip-flags -finline-functions
replace-flags -O3 -O2


_XA_CYUV_SPARC=xa1.0_cyuv_sparcELF.o
_XA_CVID_SPARC=xa2.0_cvid_sparcELF.o
_XA_IV32_SPARC=xa2.0_iv32_sparcELF.o
_XA_SPARC_EXT=.Z

_XA_CYUV_I386=xa1.0_cyuv_linuxELFg21.o
_XA_CVID_I386=xa2.0_cvid_linuxELFg21.o
_XA_IV32_I386=xa2.1_iv32_linuxELFg21.o
_XA_I386_EXT=.gz

_XA_CYUV_PPC=xa1.0_cyuv_linuxPPC.o
_XA_CVID_PPC=xa2.0_cvid_linuxPPC.o
_XA_IV32_PPC=xa2.0_iv32_linuxPPC.o
_XA_PPC_EXT=.Z

# Not much we could do here, the modules are predownloaded and
# xanim-export compiles against them
QA_EXECSTACK="usr/bin/xanim-export usr/lib/xanim/mods-export/*"

DESCRIPTION="XAnim with Quicktime and RAW Audio export functions"
HOMEPAGE="http://heroin.linuxave.net/toys.html"
SRC_URI="http://heroine.linuxave.net/xanim_exporting_edition.tar.gz
	sparc? (
		ftp://xanim.va.pubnix.com/modules/${_XA_CYUV_SPARC}${_XA_SPARC_EXT}
		ftp://xanim.va.pubnix.com/modules/${_XA_CVID_SPARC}${_XA_SPARC_EXT}
		ftp://xanim.va.pubnix.com/modules/${_XA_IV32_SPARC}${_XA_SPARC_EXT}
	)
	ppc? (
		ftp://xanim.va.pubnix.com/modules/${_XA_CYUV_PPC}${_XA_PPC_EXT}
		ftp://xanim.va.pubnix.com/modules/${_XA_CVID_PPC}${_XA_PPC_EXT}
		ftp://xanim.va.pubnix.com/modules/${_XA_IV32_PPC}${_XA_PPC_EXT}
	)
	x86? (
		ftp://xanim.va.pubnix.com/modules/${_XA_CYUV_I386}${_XA_I386_EXT}
		ftp://xanim.va.pubnix.com/modules/${_XA_CVID_I386}${_XA_I386_EXT}
		ftp://xanim.va.pubnix.com/modules/${_XA_IV32_I386}${_XA_I386_EXT}
	)"

LICENSE="XAnim"
SLOT="0"
KEYWORDS="~ppc ~sparc ~x86"
IUSE=""

RDEPEND="virtual/libc
	>=media-libs/jpeg-6b
	>=media-libs/libpng-1.2.1
	|| ( ( x11-libs/libXext
		x11-libs/libXt )
	<virtual/x11-7 )"

DEPEND="${RDEPEND}
	app-arch/ncompress
	|| ( ( x11-proto/xextproto
		x11-proto/xproto )
	<virtual/x11-7 )"

S=${WORKDIR}/xanim_exporting_edition

src_unpack() {
	case $ARCH in
		sparc)
			_XA_CYUV=$_XA_CYUV_SPARC
			_XA_CVID=$_XA_CVID_SPARC
			_XA_IV32=$_XA_IV32_SPARC
			_XA_EXT=$_XA_SPARC_EXT
			_XA_UNCOMPRESS=uncompress
			;;
		ppc)
			_XA_CYUV=$_XA_CYUV_PPC
			_XA_CVID=$_XA_CVID_PPC
			_XA_IV32=$_XA_IV32_PPC
			_XA_EXT=$_XA_PPC_EXT
			_XA_UNCOMPRESS=uncompress
			;;
		x86)
			_XA_CYUV=$_XA_CYUV_I386
			_XA_CVID=$_XA_CVID_I386
			_XA_IV32=$_XA_IV32_I386
			_XA_EXT=$_XA_I386_EXT
			_XA_UNCOMPRESS=gunzip
			;;
	esac

	unpack xanim_exporting_edition.tar.gz

	cd "${S}"/mods
	cp ${DISTDIR}/${_XA_CYUV}${_XA_EXT} .
	$_XA_UNCOMPRESS ${_XA_CYUV}${_XA_EXT}
	cp ${DISTDIR}/${_XA_CVID}${_XA_EXT} .
	$_XA_UNCOMPRESS ${_XA_CVID}${_XA_EXT}
	cp ${DISTDIR}/${_XA_IV32}${_XA_EXT} .
	$_XA_UNCOMPRESS ${_XA_IV32}${_XA_EXT}

	cd "${S}"
	rm xanim
	epatch "${FILESDIR}"/${PV}-makefile.patch

	# make compile respect CC, fix deprecated paths
	sed -i -e "/CC =/s:gcc:$(tc-getCC):" \
		-e "/INCLUDE =/s:/usr/X11R6:/usr:g" \
		-e "/XLIBDIR =/s:/usr/X11R6:/usr:" \
		Makefile || die "sed failed in Makefile"

	# make quicktime compile respect CFLAGS
	local x="$(echo \`./c_flags\`)"
	local dir="quicktime/quicktime"
	sed -i -e "s:${x}:${CFLAGS}:" \
		${dir}/Makefile || die "sed failed in ${dir}/Makefile"
}

src_compile() {
	cd "${S}"/quicktime
	make \
		CC="$(tc-getCC)" \
		XA_IV32_LIB=mods/${_XA_CYUV} \
		XA_CVID_LIB=mods/${_XA_CVID} \
		XA_CYUV_LIB=mods/${_XA_IV32} \
		|| die "make quicktime failed"
	cd ..
	make \
		XA_IV32_LIB=mods/${_XA_CYUV} \
		XA_CVID_LIB=mods/${_XA_CVID} \
		XA_CYUV_LIB=mods/${_XA_IV32} \
		OPTIMIZE="${CFLAGS}" \
		|| die "main make failed"
}

src_install() {
	newbin xanim xanim-export
	insinto /usr/lib/xanim/mods-export
	doins mods/*
	dodoc README*
	dodoc docs/README.* docs/*.readme docs/*.doc
}