dangerdeep-0.1.1.ebuild

dangerdeep-0.1.1.ebuild (text/plain), 1.16 KB, created by Tristan Heaven (RETIRED) on 2006-08-22 23:18:07 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs games

DESCRIPTION="Danger from the Deep is a World War II German submarine simulation"
HOMEPAGE="http://dangerdeep.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2 dangerdeep-artwork"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="sse"

RDEPEND="virtual/opengl
	virtual/glu
	sci-libs/fftw
	media-libs/libsdl
	media-libs/sdl-mixer
	media-libs/sdl-image
	media-libs/sdl-net"
DEPEND="${RDEPEND}
	dev-util/scons"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${P}-build.patch
}

src_compile() {
	local sse=-1
	if use sse ; then
		use amd64 && sse=3 || sse=1
	fi

	tc-export CXX
	scons \
		${MAKEOPTS} \
		usex86sse=${sse} \
		datadir="${GAMES_DATADIR}"/${PN} \
		|| die "scons failed"
}

src_install() {
	dogamesbin build/linux/${PN} || die "dogamesbin failed"

	insinto "${GAMES_DATADIR}"/${PN}
	doins -r data/* || die "doins failed"

	newicon logo.xpm ${PN}.xpm
	make_desktop_entry ${PN} "Danger from the Deep" ${PN}.xpm

	dodoc ChangeLog CREDITS README
	doman doc/man/${PN}.6

	prepgamesdirs
}