openthreads-1.4.3.ebuild

openthreads-1.4.3.ebuild (text/plain), 1.14 KB, created by Rene Meier on 2006-07-28 01:01:26 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils fixheadtails multilib toolchain-funcs

MY_PN=OpenThreads
OSG_V=1.1
DESCRIPTION="Cross-platform, lightweight C++ thread API"
HOMEPAGE="http://www.openscenegraph.org/"
SRC_URI="http://www.openscenegraph.org/downloads/snapshots/OSG_OP_OT-${OSG_V}.zip"

SLOT="0"
LICENSE="LGPL-2.1"
KEYWORDS="x86"
IUSE="doc examples"

DEPEND="doc? ( app-doc/doxygen )
		app-arch/unzip"

S=${WORKDIR}/OSG_OP_OT-${OSG_V}/${MY_PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${P}-build.patch

	ht_fix_all
}

src_compile() {
	emake CXX=$(tc-getCXX) || die "emake failed"

	if use doc ; then
		cd docs
		doxygen -u doxyfile
		doxygen doxyfile
	fi
}

src_install() {
	make INST_LOCATION="${D}"/usr install || die "make install failed"

	dosym /usr/$(get_libdir)/lib${MY_PN}.so{.${PV%%.*},} || die "dosym failed"

	use doc && dohtml docs/html/*

	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins -r examples_src/*
	fi

	insinto /usr/$(get_libdir)/pkgconfig
	doins Make/${PN}.pc

	dodoc AUTHORS.txt ChangeLog README.txt
}