nwn-prc-3.0d.ebuild

nwn-prc-3.0d.ebuild (text/plain), 2.32 KB, created by Ryan Hill (RETIRED) on 2006-07-22 22:52:25 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Player Resource Consortium is a custom content addon adding
hundreds of new classes, spells, feats and more to Neverwinter Nights"
HOMEPAGE="http://www.nwn-prc.com"
SRC_URI="PRC${PV//.}.rar"

LICENSE="as-is"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
RESTRICT="fetch"

IUSE=""

DEPEND="app-arch/unrar"
RDEPEND="${DEPEND} \
		>=games-rpg/nwn-1.66-r1"

S=${WORKDIR}

die_expansions_needed() {
	echo
	eerror "You must have both official NWN expansion packs (Shadows of"
	eerror "Undrentide and Hordes of the Underdark) installed in order for the"
	eerror "PRC Pack to work."
	echo
	eerror "If you do have these expansion packs, please rebuild nwn-data with"
	eerror "the hou and	sou USE flags enabled with the following command:"
	echo
	ewarn "  echo 'games-rpg/nwn-data hou sou' >> /etc/portage/package.use"
	ewarn "  emerge --oneshot games-rpg/nwn-data"
	die "nwn-data requires USE=hou sou"
}

pkg_nofetch() {
	einfo "Please visit http://nwvault.ign.com/View.php?view=hakpaks.Detail&id=4559"
	einfo "and download ${A}"
	echo
	einfo "Then move the file you've downloaded to "${DISTDIR}""
	echo
}

pkg_setup() {
	games_pkg_setup

	built_with_use games-rpg/nwn-data sou || die_expansions_needed
	built_with_use games-rpg/nwn-data hou || die_expansions_needed
}

src_install() {
	dodir "${GAMES_PREFIX_OPT}"/nwn/{hak,tlk,texturepacks,database}
	mv *.hak "${D}/${GAMES_PREFIX_OPT}"/nwn/hak/ || die "hak failed"
	mv *.hif "${D}/${GAMES_PREFIX_OPT}"/nwn/hak/ || die "hak failed"
	mv *.tlk "${D}/${GAMES_PREFIX_OPT}"/nwn/tlk/ || die "tlk failed"
	mv *.erf "${D}/${GAMES_PREFIX_OPT}"/nwn/texturepacks/ || die "textures failed"
	mv PRC_DATA.* "${D}/${GAMES_PREFIX_OPT}"/nwn/database/ || die "databasefiles failed"
	prepgamesdirs
}
pkg_postinst(){
	echo
	elog "Refer to the PRC manual for extensive documentation on this addon."
	elog
	elog "    http://www.nwn-prc.com/guide/index.html"
	elog
	elog "You might also want the PRC Character Creator to be able to use special races"
	elog "and new base classes from level 1"
	elog
	elog "    http://nwvault.ign.com/View.php?view=Other.Detail&id=707"
	echo
	ewarn "Don't forget to run fixinstall now to set proper permissions."
	ewarn
	ewarn "    cd ${GAMES_PREFIX_OPT}/nwn && ./fixinstall"
	echo
}