photoqt-4.5.ebuild

photoqt-4.5.ebuild (text/plain), 1.79 KB, created by Frank Krömmelbein on 2024-06-23 16:03:18 UTC

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ECM_KDEINSTALLDIRS=false
inherit ecm optfeature

DESCRIPTION="Simple but powerful Qt-based image viewer"
HOMEPAGE="https://photoqt.org/"
SRC_URI="https://photoqt.org/pkgs/${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="chromecast devil exif freeimage graphicsmagick imagemagick mpv pdf raw"

COMMON_DEPEND="
	app-arch/libarchive:=
	app-arch/unrar
	dev-libs/pugixml
	dev-qt/qtbase:6[concurrent,dbus,gui,network,sql,widgets,xml]
	dev-qt/qtdeclarative:6[network,sql,svg,widgets]
	dev-qt/qtimageformats:6
	dev-qt/qtlocation:6
	dev-qt/qtmultimedia:6[qml]
	dev-qt/qtpositioning:6[qml]
	dev-qt/qtsvg:6
	devil? ( media-libs/devil )
	exif? ( media-gfx/exiv2:=[bmff] )
	freeimage? ( media-libs/freeimage )
	imagemagick? (
		!graphicsmagick? ( media-gfx/imagemagick:=[cxx] )
		graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
	)
	mpv? ( media-video/mpv:=[libmpv] )
	pdf? ( app-text/poppler[qt6] )
	raw? ( media-libs/libraw:= )
"
#	dev-qt/qtprintsupport:5

RDEPEND="${COMMON_DEPEND}
	chromecast? ( dev-python/pychromecast )
"
#	dev-qt/qtgraphicaleffects:5
#	dev-qt/qtquickcontrols:5
#	dev-qt/qtquickcontrols2:5

BDEPEND="dev-qt/qttools:6[qdbus,linguist]
"

src_configure() {
	local mycmakeargs=(
		-DCHROMECAST=$(usex chromecast)
		-DDEVIL=$(usex devil)
		-DEXIV2=$(usex exif)
		-DEXIV2_ENABLE_BMFF=$(usex exif)
		-DFREEIMAGE=$(usex freeimage)
		-DGRAPHICSMAGICK=$(usex graphicsmagick $(usex imagemagick))
		-DIMAGEMAGICK=$(usex imagemagick $(usex !graphicsmagick))
		-DVIDEO_MPV=$(usex mpv)
		-DPOPPLER=$(usex pdf)
		-DRAW=$(usex raw)
	)
	ecm_src_configure
}

pkg_postinst() {
	optfeature "additional image formats like AVIF, EPS, HEIF/HEIC, PSD, etc." kde-frameworks/kimageformats
	ecm_pkg_postinst
}