descent2-data-1.0.ebuild

descent2-data-1.0.ebuild (text/plain), 1.40 KB, created by Paul Bredbury on 2006-06-19 15:12:18 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PV=${PV/./}

DESCRIPTION="Data files for Descent 2"
HOMEPAGE="http://www.interplay.com/games/product.asp?GameID=109"
SRC_URI="descent2.sow"
# Don't have a method of applying the ver 1.2 patch in Linux
# ftp://ftp.interplay.com/pub/patches/d2ptch${MY_PV}.exe
# mirror://3dgamers/descent2/d2ptch${MY_PV}.exe

# See readme.txt
LICENSE="${PN}"

SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE=""

RDEPEND=""
DEPEND="app-arch/unarj"

S=${WORKDIR}
dir=${GAMES_DATADIR}/d2x

pkg_setup() {
	games_pkg_setup

	if [[ ! -e "${DISTDIR}"/descent2.sow ]] ; then
		cdrom_get_cds d2data
		if [ -e "${CDROM_ROOT}"/d2data/descent2.sow ] ; then
			export CDROM_ROOT="${CDROM_ROOT}/d2data"
			einfo "Found the original Descent 2 CD"
			einfo "Copying descent2.sow to ${DISTDIR}"
			cp "${CDROM_ROOT}"/descent2.sow "${DISTDIR}"/
		else
			die "You need the original Descent 2 CD"
		fi
	fi
}

src_unpack() {
	unarj e "${DISTDIR}"/descent2.sow || die "unarj descent2.sow failed"
	rm endnote.txt
	mkdir doc
	mv *.txt doc

	# Remove files not needed by any Linux native client
	rm *.{bat,dll,exe,ini,lst}
}

src_install() {
	insinto "${dir}"
	doins * || die "doins * failed"

	dodoc doc/*

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	einfo "A client is needed to run the game, e.g. games-action/d2x-rebirth."
	echo
}