improved ebuild

mod_auth_gssapi-1.6.5.ebuild (text/plain), 1.13 KB, created by Bill Prendergast on 2023-10-31 02:51:51 UTC

# Copyright 2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit apache-module autotools tmpfiles

DESCRIPTION="GSSAPI authentication for Apache"
HOMEPAGE="https://github.com/gssapi/mod_auth_gssapi"
SRC_URI="https://github.com/gssapi/mod_auth_gssapi/releases/download/v${PV}/${PF}.tar.gz"

LICENSE="MIT"
KEYWORDS="~amd64 ~x86"
SLOT="0"

APACHE2_MOD_DEFINE="AUTH_GSSAPI"
APACHE2_MOD_CONF="11_${PN}"
DOCFILES="README"

DEPEND="
	virtual/krb5
	www-servers/apache
	dev-libs/openssl
	"
RDEPEND="${DEPEND}"

need_apache2

# Work around Bug #616612
pkg_setup() {
	_init_apache2
	_init_apache2_late
}

src_prepare() {
	default

	# The 'apxs -q LIBTOOL' query will fail and leave $(LIBTOOL) empty. However LT_INIT
	# already adds the exact value that the apxs query tries to return, so remove the apxs query
	sed -e '/^LIBTOOL="`${APXS} -q LIBTOOL`"/d' -i configure.ac || die

	eautoreconf
}

src_configure() {
	econf --with-apxs="${APXS}"
}

src_compile() {
	emake
}

src_install() {
	apache-module_src_install

	newtmpfiles "${FILESDIR}"/tmpfiles.conf ${PN}.conf
}

pkg_postinst() {
	tmpfiles_process ${PN}.conf
}