ebuild for breezy 3.3.0 which works with python 3.11

breezy-3.3.0.ebuild (text/plain), 3.60 KB, created by Marcus Comstedt on 2023-06-26 14:08:59 UTC

# Copyright 2021-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_EXT=1

PYTHON_COMPAT=( python3_{10..11} )

CRATES="
	aho-corasick-1.0.2
	autocfg-1.1.0
	bitflags-1.3.2
	cfg-if-1.0.0
	indoc-0.3.6
	indoc-impl-0.3.6
	instant-0.1.12
	lazy_static-1.4.0
	libc-0.2.147
	lock_api-0.4.10
	memchr-2.5.0
	once_cell-1.18.0
	parking_lot-0.11.2
	parking_lot_core-0.8.6
	paste-0.1.18
	paste-impl-0.1.18
	pkg-version-1.0.0
	pkg-version-impl-0.1.1
	proc-macro-hack-0.5.20+deprecated
	proc-macro2-1.0.63
	pyo3-0.15.2
	pyo3-build-config-0.15.2
	pyo3-macros-0.15.2
	pyo3-macros-backend-0.15.2
	quote-1.0.28
	redox_syscall-0.2.16
	regex-1.8.4
	regex-syntax-0.7.2
	scopeguard-1.1.0
	smallvec-1.10.0
	syn-1.0.109
	unicode-ident-1.0.9
	unindent-0.1.11
	winapi-0.3.9
	winapi-i686-pc-windows-gnu-0.4.0
	winapi-x86_64-pc-windows-gnu-0.4.0
"

inherit cargo distutils-r1 optfeature

DESCRIPTION="Distributed Version Control System with a Friendly UI"
HOMEPAGE="https://www.breezy-vcs.org/ https://github.com/breezy-team/breezy"
SRC_URI="https://launchpad.net/brz/$(ver_cut 1-2)/${PV}/+download/${P}.tar.gz
         $(cargo_crate_uris)"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="arm64 ppc64 riscv"

# Most tests don't need tests, but deselecting those that need is too hard
RESTRICT="test"
PROPERTIES="test_network"

RDEPEND="
	dev-python/configobj[${PYTHON_USEDEP}]
	dev-python/dulwich[${PYTHON_USEDEP}]
	dev-python/fastimport[${PYTHON_USEDEP}]
	dev-python/patiencediff[${PYTHON_USEDEP}]
	dev-python/fastbencode[${PYTHON_USEDEP}]
	!dev-vcs/bzr
"
BDEPEND="
	sys-devel/gettext
	dev-python/cython[${PYTHON_USEDEP}]
	test? (
		app-crypt/gpgme[python,${PYTHON_USEDEP}]
		dev-python/paramiko[${PYTHON_USEDEP}]
		dev-python/pycryptodome[${PYTHON_USEDEP}]
		dev-python/testtools[${PYTHON_USEDEP}]
	)
"

distutils_enable_tests --install unittest

src_prepare() {
	distutils-r1_src_prepare
	# Fix man instal location
	sed -e '/DATA_FILES/s/man\//share\/&/' -i setup.py || die

	# Fix call to unittest's stuff
	grep -r breezy -le 'loadTestsFromModuleNames' | xargs sed -i -e 's/loadTestsFromModuleNames/loadTestsFromNames/' || die

	# Very horrible, looks like too much, but only ~250 tests out of ~30,000.
	# Before every bump, check the need for every disable, using direct test
	# for only a specific file.
	# Don't disable tests by removing files, as this results in bad imports.
	sed -e 's/test_bzr_connect_to_bzr_ssh/_&/' -i breezy/tests/test_transport.py || die
	sed -e 's/test_is_compatible_and_registered/_&/' \
		-e 's/test_make_repository/_&/' -i breezy/plugins/weave_fmt/test_repository.py || die
	sed -e 's/test_server_exception_with_hook/_&/' -i breezy/tests/blackbox/test_serve.py || die
	sed -e 's/test_dump_/_&/' -i breezy/bzr/tests/blackbox/test_dump_btree.py || die
	sed -e 's/test_/_&/' -i breezy/plugins/fastimport/tests/test_head_tracking.py || die

	sed -e '/test_vfs_ratchet/d' -i breezy/bzr/tests/__init__.py || die
	sed -e '/test_blackbox/d' -i breezy/git/tests/__init__.py || die
	sed -e '/test_upload/d' -i breezy/plugins/upload/tests/__init__.py || die
	sed -e '/test_bzrdir/d' -i breezy/plugins/weave_fmt/__init__.py || die
	sed -e '/test_big_file/d' -i breezy/tests/blackbox/__init__.py || die
	sed -e '/breezy.tests.test_gpg/d' \
		-e '/breezy.tests.test_plugins/d' \
		-e '/breezy.tests.test_source/d' \
		-i breezy/tests/__init__.py || die
}

src_install() {
	distutils-r1_src_install

	# Symlink original bzr's bin names to new names
	dosym brz /usr/bin/bzr
}

pkg_postinst() {
	optfeature "access branches over sftp" "dev-python/pycryptodome dev-python/paramiko"
	optfeature "PGP sign and verify commits" "app-crypt/gpgme[python]"
}