HTMLtidy ebuild with man page generation

htmltidy-5.10.26-r1.ebuild (text/plain), 2.77 KB, created by Oldrich Jedlicka on 2006-05-06 03:01:57 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/htmltidy/htmltidy-5.10.26.ebuild,v 1.2 2006/04/22 22:35:59 flameeyes Exp $

inherit eutils

# Convert gentoo version number x.y.z to date xyz for
# tidy's source numbering by date
parts=(${PV//./ })
dates=$(printf "%02d%02d%02d" ${parts[0]} ${parts[1]} ${parts[2]})
MY_P=tidy_src_${dates}
S=${WORKDIR}/tidy

DESCRIPTION="Tidy the layout and correct errors in HTML and XML documents"
HOMEPAGE="http://tidy.sourceforge.net/"
SRC_URI="http://tidy.sourceforge.net/src/${MY_P}.tgz
	http://tidy.sourceforge.net/docs/tidy_docs_051020.tgz
	xml? ( http://www.cise.ufl.edu/~ppadala/tidy/html2db.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc-macos ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc xml"

DEPEND="virtual/libc
	>=sys-devel/autoconf-2.5
	>=sys-devel/automake-1.5
	dev-libs/libxslt"
RDEPEND="virtual/libc"

src_unpack() {
	unpack ${A}
	cd ${S}
	# Required to setup the source dist for autotools
	einfo "Setting up autotools for source build"
	export WANT_AUTOMAKE=1.5 WANT_AUTOCONF=2.5
	/bin/sh ./build/gnuauto/setup.sh > /dev/null

	# Stop tidy from appending -O2 to our CFLAGS
	epatch ${FILESDIR}/htmltidy-5.10.26-strip-O2-flag.patch || die

	if use xml ; then
		# Apply the docbook patch to tidy sources
		epatch ${FILESDIR}/05-${PN}-docbook.patch || die

		# And the null -> NULL patch to html2db sources
		EPATCH_OPTS="-d ${WORKDIR}" epatch ${FILESDIR}/03-html2db-null.patch || die

		# Point to the tidy source in the html2db Makefile
		sed -e "/TIDYDIR\=/s:\.\.:${S}:" \
			   -e "/LIBDIR\=/s:lib:src\/\.libs\/:" \
			   ${WORKDIR}/html2db/Makefile > ${T}/Makefile &&
		mv ${T}/Makefile ${WORKDIR}/html2db/Makefile || die "sed Makefile failed"
	fi
}

src_compile() {
	export WANT_AUTOMAKE=1.5 WANT_AUTOCONF=2.5

	einfo "Compiling htmltidy"
	econf `use_enable debug` || die
	emake || die

	if use xml ; then
		einfo "Compiling html2db"
		cd ${WORKDIR}/html2db
		emake || die
	fi

	# Generate man pages
	cd ${S}/htmldoc

	einfo "Preparing man pages"
	${S}/console/tidy -xml-help > tidy-help.xml && \
	${S}/console/tidy -xml-config > tidy-config.xml && \
	/usr/bin/xsltproc tidy1.xsl tidy-help.xml > tidy.1 || \
		die "Cannot generate man pages"
	
	einfo "Generating quick reference"
	/usr/bin/xsltproc quickref-html.xsl tidy-config.xml > quickref.html || \
		dif "Cannot generate quickref.html"
}

src_install() {
	make DESTDIR=${D} install || die
	use xml && dobin ${WORKDIR}/html2db/html2db

	cd ${S}/htmldoc
	
	# Man page
	doman tidy.1

	# 
	dodoc *.xsl

	# Install basic html documentation
	dohtml *.html *.css *.gif

	# If use 'doc' is set, then we also want to install the
	# api documentation
	use doc && dohtml -r api
}