zsnes-1.42-r1.ebuild

zsnes-1.42-r1.ebuild (text/plain), 2.13 KB, created by Robert Broglia on 2006-04-25 03:27:13 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic games

DESCRIPTION="SNES (Super Nintendo) emulator that uses x86 assembly"
HOMEPAGE="http://www.zsnes.com/ http://ipherswipsite.com/zsnes/"
SRC_URI="mirror://sourceforge/zsnes/${PN}${PV//./}src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* amd64 x86"
IUSE="debug opengl png release"
# The debug USE flag makes a "zsnesd" binary with
# debugging enabled.
# The release USE flag makes nasm run more than 2 passes.
# This means you will get a potentially more optimized binary
# at the expense of increased compile time.

RDEPEND=">=media-libs/libsdl-1.2.0
	>=sys-libs/zlib-1.1
	amd64? ( app-emulation/emul-linux-x86-sdl )
	opengl? ( virtual/opengl )
	png? ( media-libs/libpng )"
DEPEND="${RDEPEND}
	>=dev-lang/nasm-0.98
	sys-devel/automake
	>=sys-devel/autoconf-2.58"

S="${WORKDIR}/${PN}_${PV//./_}"

pkg_setup() {
	games_pkg_setup
	use amd64 && export ABI=x86
}

src_unpack() {
	unpack ${A}
	cd "${S}"/src
	cp "icons/48x48x32.png" "${T}/zsnes.png"
	epatch "${FILESDIR}"/${PV}-configure.patch
	einfo "Modifying all .asm files to have non-executable stacks"
        bash "${FILESDIR}"/tagWithNoStackExec.sh `find . -name "*.asm"`
	aclocal && autoconf || die "autotools failed"
}

src_compile() {
	# There seems to be a problem with the way 1.42's configure
	# interprets --enable/disable-debug. No matter which setting
	# is used, debugging is always enabled, so we either set
	# --enable-debug or nothing at all.
	if use debug ; then
		local debug_opt="${confopts} --enable-debug"
	fi

	cd src
	egamesconf \
		$(use_enable png libpng) \
		$(use_enable opengl) \
		${debug_opt} \
		$(use_enable release) \
		|| die
	emake || die "emake failed"
}

src_install() {
	local ZSNES_BIN=
        if use debug ; then
                ZSNES_BIN=zsnesd
        else
                ZSNES_BIN=zsnes
        fi

	dogamesbin src/${ZSNES_BIN} || die "dogamesbin failed"
	newman src/linux/zsnes.1 zsnes.6
	dodoc docs/{*.txt,README.LINUX}
	dohtml -r docs/Linux/*
	make_desktop_entry ${ZSNES_BIN} ZSNES zsnes.png
	doicon "${T}/zsnes.png"
	prepgamesdirs
}