ovpn-dco-0.1.20230206.ebuild

ovpn-dco-0.1.20230206.ebuild (text/plain), 1.07 KB, created by Timo Rothenpieler on 2023-02-15 16:41:08 UTC

# Copyright 2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit linux-mod

DESCRIPTION="OpenVPN Data Channel Offload in the linux kernel"
HOMEPAGE="https://github.com/OpenVPN/ovpn-dco"

if [[ ${PV} != 9999 ]]; then
	SRC_URI="https://github.com/OpenVPN/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
else
	inherit git-r3
	EGIT_REPO_URI="https://github.com/OpenVPN/${PN}.git"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="debug"

MODULE_NAMES="ovpn-dco(updates:.:drivers/net/ovpn-dco)"
BUILD_TARGETS="all"

pkg_setup() {
	CONFIG_CHECK="
		INET
		NET
		NET_UDP_TUNNEL
		DST_CACHE
		CRYPTO
		CRYPTO_AES
		CRYPTO_GCM
		CRYPTO_CHACHA20POLY1305"

	linux-mod_pkg_setup
}

src_compile() {
	BUILD_PARAMS+=" KERNEL_SRC='${KERNEL_DIR}'"
	[[ ${PV} != 9999 ]] && BUILD_PARAMS+=" REVISION='${PV}'"
	use debug && BUILD_PARAMS+=" DEBUG=1"
	linux-mod_src_compile
}

src_install() {
	linux-mod_src_install

	insinto /usr/share/${PN}
	doins -r include
}