dolibarr-2.0.1.ebuild

dolibarr-2.0.1.ebuild (text/plain), 4.71 KB, created by Fab on 2006-04-02 12:06:38 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils webapp depend.php

DESCRIPTION="ERP/CRM for small and medium companies"
HOMEPAGE="http://dolibarrint.jexiste.fr/en/"

# It's NOT the real URI
SRC_URI="http://netfab.ifrance.com/download/${PN}/${PV}/${P}.tgz"

# The patchset...
SRC_URI="${SRC_URI}
	http://netfab.ifrance.com/download/${PN}/${PV}/gentoo-${P}-patchset.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="unicode"

DEPEND="unicode? (app-misc/rconv)"

pkg_setup() {
	webapp_pkg_setup
	
	# we check that PHP was compiled with the correct USE flags
	if use unicode; then
		require_php_with_use curl gd mysql xml
	else
		require_php_with_use curl gd mysql
	fi
}

src_unpack() {
	unpack ${A}
	
	cd ${S}

	einfo "Generating SQL file ..."
	cd mysql && emake mysql.sql &> /dev/null && cd ..

	# ================
	#     patchs
	# ================
	# 01_all_config-file-creation.patch
	#		create dolibarr configuration file
	#
	# 02_all_mysql-db-creation.patch
	#		patch generated SQL file to create dolibarr database, 
	#		and to set default language to 'en_US'.
	#
	# 03_all_no-upgrade-available.patch
	#		no upgrade available during installation's first step.
	#
	# 04_all_install-form-inputs-disabled.patch
	#		disable some form inputs during installation.
	#
	# 05_all_install-skip-step2.patch
	#		skip step 2 (mysql's tables creation) during installation.
	#

	EPATCH_SUFFIX="patch" epatch "${WORKDIR}/gentoo-patches"



	# utf-8 hacks : dolibarr is NOT originally written to support utf-8 :
	# some files are in utf-8, others in iso-8859-1, and the application is NOT
	# 100% translated, and is in french. It make problems when apache
	# is configured with AddDefaultCharset UTF-8, and mysql is build
	# with utf8 useflag :
	#
	# We should use the header() php function (and we do !), and/or an .htaccess
	# in each directory to override the AddDefaultCharset directive, but there's
	# still problems with forms's inputs : for example, words are wrapped
	# on every 'é è à [Insert a letter with an accent]'
	# So, we add some hacks, and we convert all .php and .lang files to utf-8.
	#
	# WARNING : generated documents are NOT available in utf-8 (we convert
	# all the strings to ISO-8859-1 before generating PDF), but the web pages
	# are displayed correctly.
	if use unicode; then

		# ================
		#   utf-8 patchs
		# ================
		# 01_all_install-header.patch
		# 02_all_main-header.patch
		#		add the header() php function
		#
		# 03_all_utf8-charsets.patch
		#		modify webpage's charsets from iso-8859-1 to utf-8
		#
		# 04_all_utf8-hacks.patch
		#		various hacks for utf-8 compatibility
		#
		# 20_all_bernique-pdf-model.patch
		# 21_all_crabe-pdf-model.patch
		# 22_all_huitre-pdf-model.patch
		# 23_all_oursin-pdf-model.patch
		# 30_all_untranslated-pdf-strings.patch
		#		Untranslated strings in .php files makes problems with utf-8
		#		in generated PDF. We extract all the strings in a .lang file,
		#		and they are finally decoded (with our previous hacks)
		#		from utf-8 to ISO-8859-1 before PDF generation.

		EPATCH_SUFFIX="patch" epatch "${WORKDIR}/gentoo-utf8-patches"

		local RCONV_PATH='/usr/bin/rconv'

		# finally, converting all the .php files to utf-8, recursively.
		einfo "Converting php files to utf-8 ..."
		eval "$RCONV_PATH --dir=htdocs --mimetype=text/x-c &> /dev/null"

		# we don't forget the .lang files.
		einfo "Converting language files to utf-8 ..."
		eval "$RCONV_PATH --dir=htdocs/langs --mimetype=text/plain &> /dev/null"

		# copying PDF untranslated strings's file to each language directory
		local UNTRANSLATED_FILE='gentoo-untranslated-pdf-strings.lang'
		cd htdocs/langs

		for directory in *; do
			if [ -d $directory ] && [ $directory != 'fr_FR' ]; then
				cp fr_FR/$UNTRANSLATED_FILE $directory
			fi
		done

	fi

}

src_install() {
	webapp_src_preinst

	cd ${S}

	webapp_sqlscript mysql mysql/mysql.sql

	local ARI="doc/install"
	local ARU="doc/user"

	# WARNING : install instructions are deprecated,
	# and documents are only in french.
	# Example : PEAR Base System is already included in dolibarr's code.
	local docs="
		README README-FR ChangeLog COPYING COPYRIGHT doc/Mysql
		${ARI}/dolibarr-install.pdf ${ARI}/dolibarr-install.txt
		${ARU}/dolibarr-user.pdf ${ARU}/dolibarr-user.txt"

	dodoc ${docs}

	dohtml ${ARI}/dolibarr-install-1.html ${ARI}/dolibarr-install-2.html \
			${ARI}/dolibarr-install-3.html ${ARI}/dolibarr-install.html

	einfo "Installing main files"
	cd htdocs
	cp -r . ${D}${MY_HTDOCSDIR}

	webapp_postinst_txt en ${FILESDIR}/${PV}/postinstall-en.txt

	# Set correct permissions on the configuration file
	webapp_hook_script ${FILESDIR}/conf-file-perms

	webapp_src_install
}