legends-0.4.1.39.ebuild

legends-0.4.1.39.ebuild (text/plain), 2.08 KB, created by Jiri Tyr on 2006-03-30 16:45:29 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/legends/legends-0.4.1c.ebuild,v 1.6 2005/10/10 19:12:38 mr_bones_ Exp $

inherit games

MY_P=${PN}_linux_${PV}
DESCRIPTION="A fast-paced first-person-perspective online multiplayer game similar to Tribes"
HOMEPAGE="http://legendsthegame.net/"
SRC_URI="http://legends.sciesnet.net/${MY_P}.sh
	 mirror://gentoo/${PN}.png
	 http://dev.gentoo.org/~wolf31o2/sources/dump/${PN}.png"

RESTRICT="nomirror"
KEYWORDS="~x86"
LICENSE="as-is"
SLOT="0"
IUSE="dedicated"

DEPEND=""
RDEPEND=">=media-libs/libsdl-1.2
	media-libs/libogg
	media-libs/libvorbis
	media-libs/openal
	amd64? ( >=app-emulation/emul-linux-x86-sdl-2.1
		 >=app-emulation/emul-linux-x86-soundlibs-2.1 )"

S=${WORKDIR}/${MY_P}

src_unpack() {
	local LIBSDL=libSDL-1.3.so.0

	tail +91 ${DISTDIR}/${MY_P}.sh 2>/dev/null | tar -C ${WORKDIR} -xjf -
	cd "${WORKDIR}"

	# keep libSDL-1.3.so because legends requires it as of 0.4.0, and
	# 1.2.6 is highest in portage
	# rm libSDL-*.so*
	rm runlegends libSDL-1.2.so.0 libopenal.so libogg.so.0 libvorbis.so.0 *.DLL
	find . -type f -exec chmod a-x '{}' \;
	chmod a+x lindedicated LinLegends

	cp "${FILESDIR}"/legends{,-ded} "${T}" || die "cp failed"

	sed -i \
		-e "s:GENTOO_DIR:${GAMES_PREFIX_OPT}/${PN}:" \
		-e "s:LIBSDL:${LIBSDL}:" \
		"${T}"/legends{,-ded} \
		|| die "sed failed"
}

src_install() {
	local dir="${GAMES_PREFIX_OPT}/${PN}"

	dogamesbin "${T}/legends" || die "dogamesbin failed (1)"
	keepdir "${dir}/"{show/ui,show/scripts,legends/scripts,legends/data,common/server,common/edit,common/client}
	cd ${WORKDIR}
	cp -R * "${D}${dir}/" || die "cp failed"
	if use dedicated ; then
		dogamesbin "${T}"/legends-ded || die "dogamesbin failed (2)"
	fi
	doicon "${DISTDIR}"/${PN}.png
	make_desktop_entry legends "Legends"
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	echo
	einfo "Version ${PV} of ${PN} may give problems if there are"
	einfo "config-files from earlier versions.  Removing the ~/.legends dir"
	einfo "and restarting will solve this."
	echo
}