initng-9999.ebuild

initng-9999.ebuild (text/plain), 2.13 KB, created by Thomas Kear on 2006-03-09 03:01:15 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
#

ESVN_REPO_URI="http://svn.initng.thinktux.net/initng/trunk"
ESVN_PROJECT="initng"
inherit subversion eutils

DESCRIPTION="A next generation init replacement"
HOMEPAGE="http://initng.thinktux.net/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-*"

IUSE_INITNG_PLUGINS="initng_plugins_also initng_plugins_bash_launcher
	initng_plugins_chdir initng_plugins_chroot initng_plugins_conflict
	initng_plugins_cpout initng_plugins_critical initng_plugins_cron
	initng_plugins_daemon initng_plugins_dev initng_plugins_dllaunch
	initng_plugins_doc initng_plugins_envparser initng_plugins_find
	initng_plugins_fstat initng_plugins_history initng_plugins_idleprobe
	initng_plugins_initctl initng_plugins_interactive initng_plugins_iparser
	initng_plugins_jbx initng_plugins_last initng_plugins_limit
	initng_plugins_logfile initng_plugins_netprobe initng_plugins_ngc2
	initng_plugins_ngcs initng_plugins_pause initng_plugins_pidfile
	initng_plugins_reload initng_plugins_renice initng_plugins_rlparser
	initng_plugins_simple_launcher initng_plugins_splash initng_plugins_stcmd
	initng_plugins_stdout initng_plugins_suid initng_plugins_syncron
	initng_plugins_syslog initng_plugins_unneeded initng_plugins_usplash"
IUSE="${IUSE_INITNG_PLUGINS} debug"

S=${WORKDIR}/${PN}

pkg_preinst() {
	ewarn "All plugins are disabled by default, check USE flags"
}

src_unpack() {
	subversion_src_unpack
	cd "${S}"
	emake -fMakefile.cvs
}

src_compile() {
	ECONF_OPTS="--prefix=/ --with-doc-dir=/usr/share/doc/${PF} $(use_enable debug)"
	for plugin in ${IUSE_INITNG_PLUGINS}
	do
		ECONF_OPTS="${ECONF_OPTS} $(use_with ${plugin} ${plugin#initng_plugins_})"
	done
	econf ${ECONF_OPTS} || die
	emake || die
}

src_install() {
	make install DESTDIR="${D}" || die
	# Dont need libtool linker scripts, so punt em
	find "${D}" -name '*.la' -exec rm {} \;
	dodoc README FAQ AUTHORS ChangeLog NEWS TEMPLATE_HEADER TODO
}

pkg_postinst() {
	einfo "remember to add init=/sbin/initng in your grub or lilo config"
	einfo "to use initng Happy testing."
	einfo "don't remember to install sys-apps/initng-ifiles."
}