musepack-tools ebuild for ppc (mppdec only)

musepack-tools-1.15v-r1.ebuild (text/plain), 1.80 KB, created by Dirk Silkenbäumer on 2006-03-03 04:47:04 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/musepack-tools/musepack-tools-1.15v.ebuild,v 1.6 2005/10/18 21:46:37 chainsaw Exp $

IUSE="static 16bit esd"

inherit eutils flag-o-matic

S="${WORKDIR}/sv7"

DESCRIPTION="Musepack audio compression tools"
HOMEPAGE="http://www.musepack.net"
SRC_URI="http://files.musepack.net/source/mpcsv7-src-${PV}.tar.bz2"

SLOT="0"
LICENSE="LGPL-2.1"
KEYWORDS="~amd64 x86"

RDEPEND="esd? ( media-sound/esound )
	 media-libs/id3lib"

DEPEND="${RDEPEND}
	x86? ( dev-lang/nasm )
	amd64? ( dev-lang/nasm )"

src_unpack() {
	unpack ${A}
	cd ${S}

	if use ppc; then
		mv Makefile.Darwin Makefile
		epatch ${FILESDIR}/${P}-Makefile-ppc.patch
	else
		epatch ${FILESDIR}/${P}-Makefile.patch
		epatch ${FILESDIR}/${P}-gcc4.patch
	fi
	
	sed -i 's/#define USE_IRIX_AUDIO/#undef USE_IRIX_AUDIO/' mpp.h

	if ! use esd ; then
		sed -i -e 's/#define USE_ESD_AUDIO/#undef USE_ESD_AUDIO/' mpp.h
	else
		sed -i -e 's/^LDADD    = -lm$/LDADD    = $(shell esd-config --libs)/' \
			Makefile
	fi

	if ! use x86 ; then
		sed -i 's/#define USE_ASM/#undef USE_ASM/' mpp.h
	fi

	use 16bit && sed -i 's|//#define MAKE_16BIT|#define MAKE_16BIT|' mpp.h

	# Bug #109699; console redirection to /dev/tty makes no sense
	sed -i -e 's/$(LDADD) &> $(LOGFILE)/$(LDADD)/' Makefile
}

src_compile() {
	filter-flags "-fprefetch-loop-arrays"
	filter-flags "-mfpmath=sse" "-mfpmath=sse,387"
	use static && export BLD_STATIC=1

	append-flags -I${S}
	if use ppc; then
		replace-flags -O* -O1
		ARCH= emake mppdec || die
	else
		ARCH= emake mppenc mppdec replaygain || die
	fi
}

src_install() {
	if use ppc; then
		dobin mppdec
	else
		dobin mppenc mppdec replaygain
	fi
	dodoc README doc/ChangeLog doc/MANUAL.TXT doc/NEWS doc/SV7.txt doc/TODO*
}