mod_python-3.2.8.ebuild

mod_python-3.2.8.ebuild (text/plain), 1.97 KB, created by Sam D. Chuparkoff on 2006-02-23 13:25:32 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit python eutils apache-module autotools

DESCRIPTION="An Apache2 DSO providing an embedded Python interpreter"
HOMEPAGE="http://www.modpython.org/"
SRC_URI="mirror://apache/httpd/modpython/${P}.tgz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE=""
DEPEND=">=dev-lang/python-2.2.1"

APACHE2_MOD_CONF="${PVR}/16_mod_python"
APACHE2_MOD_DEFINE="PYTHON"

DOCFILES="README NEWS CREDITS NOTICE LICENSE"

need_apache2

export TEST_SERVER_ROOT="${T}/test"
export TEST_USER="portage"
export TEST_GROUP="portage"

src_unpack() {
	unpack ${A} || die "unpack failed"
	cd ${S} || die "cd \$S failed"

	# remove optimisations, we do that outside portage
	sed -i -e 's:--optimize 2:--no-compile:' dist/Makefile.in

	# fix configure with bash 3.1
	# svn log -r376555 http://svn.apache.org/repos/asf
	epatch "${FILESDIR}/${PVR}/configure-bash-3.1.upstream.patch"

	# svn log -r376544 http://svn.apache.org/repos/asf
	epatch "${FILESDIR}/${PVR}/apache-2.2-support.upstream.patch"

	epatch "${FILESDIR}/${PVR}/gentoo-testing.patch"
	eautoconf
}

src_compile() {
	# TEST_* values will be substituted in test/testconf.py
	econf --with-apxs=${APXS2} || die "econf failed"

	emake OPT="`apxs2 -q CFLAGS` -fPIC" || die "emake failed"
}

src_test() {
	# tests need to be accessible to apache running as portage:portage
	cp -a test "${TEST_SERVER_ROOT}" \
	    || die "cannot populate test directory: ${TEST_SERVER_ROOT}"

	python "${TEST_SERVER_ROOT}/test.py" || die "test failed"
}

src_install() {
	emake DESTDIR=${D} install || die

	dohtml doc-html/*
	insinto /usr/share/doc/${PF}/html/icons
	doins doc-html/icons/*

	insinto /usr/share/doc/${PF}/examples
	doins examples/*

	apache-module_src_install
}

pkg_postinst() {
	python_version
	python_mod_optimize /usr/lib/python${PYVER}/site-packages/mod_python
	apache-module_pkg_postinst
}

pkg_postrm() {
	python_mod_cleanup
}