Citadel 6.70 net-mail ebuild

citadel-6.70.ebuild (text/plain), 4.32 KB, created by Christopher Hogan on 2006-02-19 07:10:56 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Advanced multiprotocol messaging and collaboration server"
HOMEPAGE="http://www.citadel.org/"
SRC_URI="http://easyinstall.citadel.org/${P}.tar.gz"
RESTRICT="primaryuri"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc"
IUSE="ldap ssl zlib pam ncurses newt"
S=${WORKDIR}/${PN}
MESSAGEBASE="/var/lib/citadel"

#should I bring in the calendar use flag?

DEPEND="!mail-mta/citadel
	>=dev-libs/libical-0.26.6
	>=sys-devel/autoconf-2.53
	>=sys-libs/db-4.1.25_p1
	ldap? ( >=net-nds/openldap-2.0.27 )
	ssl? ( >=dev-libs/openssl-0.9.6 )
	zlib? ( >=sys-libs/zlib-1.1.4 )
	pam? ( sys-libs/pam )
	ncurses? ( sys-libs/ncurses )
	newt? ( dev-libs/newt )"

src_compile() {
	#Directory locations borrowed from citadel/debian/rules
	econf \
		--prefix=/usr/sbin \
		--with-sysconfdir=/etc/citadel \
		--with-spooldir=/var/spool/citadel \
		--with-datadir=${MESSAGEBASE} \
		--with-rundir=/var/run/citadel \
		--with-docdir=/usr/share/doc/${PF}/ \
		$(use_with pam) \
		$(use_with ssl openssl) \
		$(use_with zlib) \
		$(use_with ldap) \
		$(use_with ncurses) \
		$(use_with newt) \
		--with-libical \
		--with-db \
		--enable-autologin \
	|| die "./configure failed"

	#emake server utils || die "make failed"
	#Tried this. However, it still makes client binaries.
	emake || die "make failed"
}

src_install() {
	#Moved from pkg_preinst as Emerge now runs src_install
	#before pkg_preinst

        #Create the user/group that the sever will run as.
        #Homedir needs to be the same as --with-datadir
        einfo "Adding Citadel User/Group"
        enewgroup citadel 175
        enewuser citadel 175 /dev/null ${MESSAGEBASE} citadel

	if use pam ; then
		dodir /etc/pam.d
	fi

	make root=${D} install-new || die "make install failed"

	keepdir /var/lib/citadel/data

	#Remove the client files
	#Emerge net-mail/citadel-client to get them back
	rm ${D}/usr/bin/citadel
	rm ${D}/etc/citadel/citadel.rc

	#/usr/sbin is a bad place to keep a generic setup
	#Debian puts it in /usr/lib/citadel-server
	#However, /usr/lib is for programs that are run by programs
	mv ${D}/usr/sbin/setup ${D}/usr/sbin/citsetup

	#Fix some permissions
	fowners citadel:citadel /etc/citadel

	#Work around some sendmail problems
	rm ${D}/usr/sbin/sendmail
	fowners root:citadel /usr/sbin/citmail
	fperms 4755 /usr/sbin/citmail

	if use ldap ; then
		insinto /etc/openldap/schema
		doins citadel-openldap.schema
	fi

	prepall
	prepalldocs
}

pkg_postinst() {
	einfo
	einfo "You might want to run:"
	einfo "\"emerge --config =${CATEGORY}/${PF}\""
	einfo "if this is a new install."
	einfo
}

pkg_config() {
	#Citadel's setup uses a few enviromental variables to control it.
	#Read techdoc/package-setup.txt for information
	#
	export CITADEL_INSTALLER="yes"
	#Citadel home
	export CITADEL=${MESSAGEBASE}
	#Is citadel the MTA? In this ebuild, no. However, it could be with the MTA ebuild...
	export ACT_AS_MTA="no"
	#Don't create the inittab entry. We'll create it latter
	export CREATE_INITTAB_ENTRY="no"
	export CREATE_XINETD_ENTRY="no"
	#Warn user of possible bugs in setup...
	ewarn "Be sure to set the Server port number to 504"

	#/usr/sbin/citsetup -q will create the config using defaults and enviromental variables.
	#However, there are just too many questions I don't want to have answered in make.conf
	/usr/sbin/citsetup

	#Verify the /etc/services entry was made
	if [ -f /etc/services ] && ! grep -q '^citadel' /etc/services ; then
		echo "citadel		504/tcp		# citadel" >> /etc/services
	fi

	#citsetup creates the wrong path for citserver.
	#We'll create the /etc/inittab entry here
	if [ -f /etc/inittab ] ; then
		grep -v 'citserver' /etc/inittab >/etc/inittab.new && \
		echo "cit1:2345:respawn:/usr/sbin/citserver -h/var/lib/citadel -x5 -llocal4" >> /etc/inittab.new && \
		mv -f /etc/inittab.new /etc/inittab
		/sbin/init q
	fi

	einfo "Citadel has been started."
	einfo
	einfo "Be sure to read the documentation in /usr/share/doc/${PF}"
	einfo "You will also want a client installed somewhere in your net:"
	einfo "net-mail/citadel-client provides a text client"
	einfo "www-apps/webcit provides a web-based client"
	einfo
}

pkg_prerm() {
	if [ -f /etc/inittab ] ; then
		grep -v 'citserver' < /etc/inittab > /etc/inittab.new && \
		mv -f /etc/inittab.new /etc/inittab
		/sbin/init q
	fi
}