freecolor-0.8.7.ebuild

freecolor-0.8.7.ebuild (text/plain), 977 bytes, created by Adrian Frühwirth on 2006-02-04 12:47:15 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="Freecolor displays free memory as a bargraph in console"
HOMEPAGE="http://www.rkeene.org/oss/freecolor/"
SRC_URI="http://www.rkeene.org/files/oss/${PN}/${P}.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE="libstatgrab"

DEPEND="libstatgrab? ( sys-libs/libstatgrab )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Checks for deprecated functions although using the proper ones.
	# Since we compile libstatgrab with --disable-deprecated, it breaks.
	sed -i \
		-e 's:get_memory_stats:sg_get_mem_stats:g' \
		-e 's:statgrab_drop_privileges:sg_drop_privileges:g' \
		aclocal.m4 \
		|| die "sed failed"
}

src_compile() {
	aclocal -I . || die
	autoconf || die

	econf \
		$(use_with libstatgrab) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	newbin free freecolor || die "newbin failed"
	dodoc ChangeLog README
}