lostlabyrinth-bin-2.3.4.ebuild

lostlabyrinth-bin-2.3.4.ebuild (text/plain), 1.29 KB, created by Paul Bredbury on 2006-01-31 23:39:30 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PN="lostlabyrinth"

DESCRIPTION="Lost Labyrinth, a Rogue-like game"
HOMEPAGE="http://www.lostlabyrinth.com/
	http://laby.toybox.de"
SRC_URI="mirror://sourceforge/lostlaby/${MY_PN}_${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="nostrip"

DEPEND=">=media-libs/libsdl-1.2.8-r1
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"

S=${WORKDIR}/laby_${PV}
dir=${GAMES_PREFIX_OPT}/${MY_PN}
exe="laby"

src_install() {
	local statedir=${GAMES_STATEDIR}/${MY_PN}

	insinto "${statedir}"
	doins highscores.dat settings.txt || die

	# Set up links for writeable files
	dodir "${dir}"
	for filename in {highscores.dat,settings.txt,savenames.sav,laby{1,2,3,4,5,6,7,8,9,10}.sav}; do
		touch "${D}${statedir}/${filename}" || die
		dosym "${statedir}/${filename}" "${dir}/${filename}" || die
		fperms 660 "${statedir}/${filename}" || die
	done

	insinto "${dir}"
	exeinto "${dir}"
	rm highscores.dat settings.txt
	doins * || die
	doexe ${exe}

	newicon laby.xpm ${MY_PN}.xpm
	games_make_wrapper ${MY_PN} "${dir}/${exe}" "${dir}"
	make_desktop_entry ${MY_PN} "Lost Labyrinth" ${MY_PN}.xpm

	prepgamesdirs
}