gpsbabel-1.8.0.ebuild

file_852836.txt (text/plain), 1.23 KB, created by Sam James on 2022-06-17 20:11:30 UTC

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

# As of 1.8.0, the CMake build is still experimental, and doesn't work for
# e.g. install. See http://www.gpsbabel.org/htmldoc-development/Source.html for
# status before porting to it.
inherit qmake-utils

MY_PV="${PV//./_}"
MY_P="${PN}_${MY_PV}"

DESCRIPTION="GPS waypoints, tracks and routes converter"
HOMEPAGE="https://www.gpsbabel.org/ https://github.com/gpsbabel/gpsbabel"
if [[ ${PV} == 9999 ]] ; then
	EGIT_REPO_URI="https://github.com/gpsbabel/gpsbabel.git"
	inherit git-r3
else
	SRC_URI="https://github.com/gpsbabel/gpsbabel/archive/gpsbabel_${MY_PV}.tar.gz"
	KEYWORDS="~amd64 ~ppc ~x86"
fi

S="${WORKDIR}/${PN}-${MY_P}"

LICENSE="GPL-2"
SLOT="0"
IUSE="webengine"

DEPEND="
	dev-qt/qtcore:5
	sci-libs/shapelib:=
	sys-libs/zlib
	virtual/libusb:1
	webengine? ( dev-qt/qtwebengine:5 )
"
RDEPEND="${DEPEND}"
BDEPEND="virtual/pkgconfig"

src_prepare() {
	default

	# Ensure bundled libs are not used
	rm -r shapelib zlib || die
}

src_configure() {
	eqmake5 \
		WITH_LIBUSB=pkgconfig \
		WITH_SHAPELIB=pkgconfig \
		WITH_ZLIB=pkgconfig \
		$(usex webengine '' 'CONFIG+=disable-mappreview')
}